Get page number from object

[catflap]

Hi



I have a macro that loops through the text boxes in a multi-page word document and shrinks the text if it's overflowing:

For Each oShp In ActiveDocument.Shapes
      If oShp.Type = msoTextBox Then
            Do While ActiveDocument.Shapes(oShp.Name).TextFrame.Overflowing  
                  ActiveDocument.Shapes(oShp.Name).TextFrame.TextRange.Font.Shrink
            Loop
      End if
Next

Is there a nice little line I can out in here which I can use to tell the page number as the loop goes through? I have it in mind to display this on the statusbar so I get some indication of progress.

Thanks!

[macropod]

Try something based on:

Sub Demo()
Dim SBar As Boolean, oShp As Shape, i As Long, j As Long
With Application
  .ScreenUpdating = False
  SBar = .DisplayStatusBar
  .DisplayStatusBar = True
End With
For Each oShp In ActiveDocument.Shapes
  With oShp
    i = .Anchor.Information(wdActiveEndPageNumber)
    If i <> j Then
      StatusBar = "Processing page: " & i
      j = i
    End If
    If .Type = msoTextBox Then
      Do While .TextFrame.Overflowing
        .TextFrame.TextRange.Font.Shrink
      Loop
    End If
  End With
Next
With Application
  .StatusBar = False
  .DisplayStatusBar = SBar
  .ScreenUpdating = True
End With
End Sub

[catflap]

wow - comprehensive reply!

I'll give it a go - thanks.

UPDATE - Yep, works a treat! - cheers