Replacing text held in all bookmarks

[THH4929]

Hello all,




I'm new to the whole VBA in word, and am struggling to resolve this issue!!!


What I am trying to achieve is to have a doc with various bookmarks, when a script is run, vba systematically goes through all bookmarks, requests user input via an inputbox, and then replaces the text with the user determined text.


This is what I have so far;

Sub UpdateBookmarks()

Dim bmInput As String

For Each bm In ActiveDocument.Bookmarks
    bmInput = InputBox("Please enter " & bm.Name)
    UpdateBM ActiveDocument, bm.Name, bmInput
Next

End Sub

Sub UpdateBM(ByRef bmDoc As Document, bmName As String, bmContent As String)
Dim bmRng As Word.Range
    Set bmRng = bmDoc.Bookmarks(bmName).Range
    bmRng.Text = bmContent
End Sub

However, when I run the code, it inserts the user input at the beginning of the text already present in the bookmark, rather than replacing it.


Please can anyone help??
Many thanks all

[macropod]

Most likely the issue is that the text you're seeking to update isn't actually bookmarked - even your own code doesn't ensure that. You need to insert:
bmDoc.Bookmarks.Add bmName, bmRng
after:
bmRng.Text = bmContent

[gmayor]

Originally Posted by THH4929

However, when I run the code, it inserts the user input at the beginning of the text already present in the bookmark, rather than replacing it.

See the FillBM function (and other handy functions) at https://www.gmayor.com/useful_vba_functions.htm

[gmaxey]

or this:

Sub UpdateBookmarks()
Dim lngIndex As Long
Dim oRng As Range
Dim strName As String
  With ActiveDocument
    For lngIndex = 1 To .Bookmarks.Count
      Set oRng = .Bookmarks(lngIndex).Range
      strName = .Bookmarks(lngIndex).Name
      oRng.Text = InputBox("Please enter " & strName)
      .Bookmarks.Add strName, oRng
    Next
  End With
lbl_Exit:
  Exit Sub
End Sub

[THH4929]

Thank you for your replies, however the suggestions from Macropod only seems to loop the first BM, similar to that of Gmayor, I have attached a copy of the test word doc for additional review.


gmaxey suggestion seems to do the trick, however, is there a way of sequencing the bookmarks to the user completes the details in a logical manor, ie. CompName, CompAddress, CompTel, rather than the character sort of CompAddress, COmpName, CompTel.


Many thanks once again for your help on this.

[macropod]

The problem isn't with anything that Graham or I posted but with the the wrong kind of loop being used in your own code. Try:

Sub UpdateBookmarks()
Dim i As Long
With ActiveDocument
  For i = 1 To .Bookmarks.Count
    With .Bookmarks(i)
      Call UpdateBM(.Name, InputBox("Please enter " & .Name))
    End With
  Next
End With
End Sub

Sub UpdateBM(bmName As String, bmContent As String)
Dim bmRng As Word.Range
With ActiveDocument
  Set bmRng = .Bookmarks(bmName).Range
  bmRng.Text = bmContent
  .Bookmarks.Add bmName, bmRng
End With
End Sub

[gmaxey]

If you name your bookmarks with a logical processing manner in mind then yes.

Sub UpdateBookmarks()
Dim lngIndex As Long, lngPart As Long
Dim oRng As Range
Dim strName As String, strDisplay As String
Dim arrParts() As String
  With ActiveDocument
    For lngIndex = 1 To .Bookmarks.Count
      Set oRng = .Bookmarks(lngIndex).Range
      strName = .Bookmarks(lngIndex).Name
      arrParts = Split(strName, "_")
      If UBound(arrParts) > 0 Then
        'For processing bookmarks names using following convention: _
         A_Complany_Name, B_Company_Address, etc.
        strDisplay = vbNullString
        For lngPart = 1 To UBound(arrParts)
          strDisplay = strDisplay & " " & arrParts(lngPart)
        Next
        oRng.Text = InputBox("Please enter " & strDisplay)
      Else
        oRng.Text = InputBox("Please enter " & strName)
      End If
      .Bookmarks.Add strName, oRng
    Next
  End With
lbl_Exit:
  Exit Sub
End Sub