PAGE and NUMPAGES fields in footer ??

[ksor]

I made this short method to setup a header/footer in a word document:

Public Sub headerFooter(f As Form, bD As Word.Document)
    With bD.Sections(1)
        .Headers(wdHeaderFooterPrimary).Range.Text = "Alle registrerede data vedr. PersonId: " & f.PersonID & " " & HentFMENavn(f.PersonID)
        .Footers(wdHeaderFooterPrimary).Range.Text = "Sammensat " & StrConv(Format(Date, "dddd"), vbProperCase) & " den " & Date & vbTab & vbTab & "Side "
        .Footers(wdHeaderFooterPrimary).Range.Fields.add Selection.Range, wdFieldEmpty, "PAGE  ", True
        .Footers(wdHeaderFooterPrimary).Range.Text = " af "
        .Footers(wdHeaderFooterPrimary).Range.Fields.add Selection.Range, wdFieldEmpty, "NUMPAGES  ", True
    End With
End Sub

BUT the actual digits for the fields PAGE and NUMPAGES is NOT writen in the footer - they are writen in the normal text area !



What do I need to change in the code ?

EDIT: Now I see I should have posted in WORD VBA - sorry !

[macropod]

I'd be surprised if any of the footer content was correct with that code - as posted all you'd end up with in the footer is ' af ', since:

.Footers(wdHeaderFooterPrimary).Range.Text = " af "

overwrites whatever is already there and:

.Footers(wdHeaderFooterPrimary).Range.Fields.add Selection.Range

adds the field to whatever is selected - which is probably not in the footer.

Try:

Public Sub headerFooter(f As Form, bD As Word.Document)
    With bD.Sections(1)
        .Headers(wdHeaderFooterPrimary).Range.Text = "Alle registrerede data vedr. PersonId: " & f.PersonID & " " & HentFMENavn(f.PersonID)
        With .Footers(wdHeaderFooterPrimary).Range
            .Text = "Sammensat " & StrConv(Format(Date, "dddd"), vbProperCase) & " den " & Date & vbTab & vbTab & "Side "
            .Fields.Add .Characters.Last, wdFieldEmpty, "PAGE", False
            .InsertAfter " af "
            .Fields.Add .Characters.Last, wdFieldEmpty, "NUMPAGES", False
        End With
    End With
End Sub

[ksor]

it is working nicely

thx !

[Charles Kenyon]

I would strongly urge you to consider using a Template or Header AutoText/ Building Block for this. IMO, it is much easier to fine-tune.

This recommendation may speak to my (lack of) vba coding skills. However, I have long found use of built-in capabilities of Word to be superior to coding when both can produce the same result. It may well be that you need to do it as part of a longer procedure. However, creating a document through code rather than using a template seems like an exercise in frustration.