Copy the only page in Word document a given number of times in VBA

[dpashley]

What I need to do is take a set page in a Word document and duplicate (copy & paste) it a set number of times using VBA.

The desired solution is a function that I am able to pass in the number of additional pages I want. The function would then take the only page in the document and add this number of exact copies to the end.

Thanks in advance for any help,



Dan

[macropod]

If you insert a next page section break at the end of the document, unlinking that section's headers/footers from those of the previous sections, then put the entire page you want to replicate into the last Section's header, the following macro will let you make as many copies of that page as you require.

Sub LastPageCopier()
Application.ScreenUpdating = False
Dim iCount As Long, i As Long
On Error GoTo Done
iCount = InputBox("How many of the last page do you need?", "Last Page Copier", 2)
If IsNumeric(iCount) = False Then GoTo Done: If iCount < 2 Then GoTo Done
For i = 1 To iCount
  ActiveDocument.Range.InsertAfter Text:=Chr(12)
Next
Done:
Application.ScreenUpdating = True
End Sub

[gmayor]

While Paul's suggestion is ingenious, you could also do it without modifying the document:

Sub CopyPage()
Dim oRng As Range, oEnd As Range
Dim lngCopies As Long, i As Long
    lngCopies = InputBox("How many copies?")
    Set oRng = ActiveDocument.Bookmarks("\page").Range
    For i = 1 To lngCopies
        ActiveDocument.Range.InsertAfter Chr(12)
        Set oEnd = ActiveDocument.Range
        oEnd.Collapse 0
        oEnd.FormattedText = oRng.FormattedText
    Next i
lbl_Exit:
    Set oRng = Nothing
    Set oEnd = Nothing
    Exit Sub
End Sub

If you have a page number field in your document, you need to decide how you want the numbering to appear in the finished document. If you want 1 on each page then change the field for '1' as text; however if you do that it is difficult to see the point of the document. If you want to print a number of copies then why duplicate them first? If you want numbered printed copies then see http://www.gmayor.com/automatic_numbering_documents.htm

[dpashley]

That worked perfectly!

Thank you!