Microsoft Office Forums

Go Back   Microsoft Office Forums > >

Reply
 
Thread Tools Display Modes
  #1  
Old 10-30-2017, 01:45 PM
AngelaSWard AngelaSWard is offline Easy way to remove comments in bulk? Windows 7 64bit Easy way to remove comments in bulk? Office 2013
Novice
Easy way to remove comments in bulk?
 
Join Date: May 2014
Location: Fresno, CA
Posts: 11
AngelaSWard is on a distinguished road
Cool Easy way to remove comments in bulk?

I have 200+ documents that need comments removed. Any tricks?
Reply With Quote
  #2  
Old 10-30-2017, 05:49 PM
macropod's Avatar
macropod macropod is offline Easy way to remove comments in bulk? Windows 7 64bit Easy way to remove comments in bulk? Office 2010 32bit
Administrator
 
Join Date: Dec 2010
Location: Canberra, Australia
Posts: 21,956
macropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond repute
Default

You would need a macro for that. For example:
Code:
Sub DeleteDocumentComments()
Application.ScreenUpdating = False
Dim strFolder As String, strFile As String, strDocNm As String, wdDoc As Document, i As Long
strDocNm = ActiveDocument.FullName
strFolder = GetFolder
If strFolder = "" Then Exit Sub
strFile = Dir(strFolder & "\*.doc", vbNormal)
While strFile <> ""
  If strFolder & "\" & strFile <> strDocNm Then
    Set wdDoc = Documents.Open(FileName:=strFolder & "\" & strFile, AddToRecentFiles:=False, Visible:=False)
    With wdDoc
      If .Comments.Count > 0 then .DeleteAllComments
      .Close SaveChanges:=True
    End With
  End If
  strFile = Dir()
Wend
Set wdDoc = Nothing
Application.ScreenUpdating = True
End Sub

Function GetFolder() As String
Dim oFolder As Object
GetFolder = ""
Set oFolder = CreateObject("Shell.Application").BrowseForFolder(0, "Choose a folder", 0)
If (Not oFolder Is Nothing) Then GetFolder = oFolder.Items.Item.Path
Set oFolder = Nothing
End Function
For PC macro installation & usage instructions, see: http://www.gmayor.com/installing_macro.htm
__________________
Cheers,
Paul Edstein
[Fmr MS MVP - Word]
Reply With Quote
  #3  
Old 10-31-2017, 06:49 AM
AngelaSWard AngelaSWard is offline Easy way to remove comments in bulk? Windows 7 64bit Easy way to remove comments in bulk? Office 2013
Novice
Easy way to remove comments in bulk?
 
Join Date: May 2014
Location: Fresno, CA
Posts: 11
AngelaSWard is on a distinguished road
Default

Thank you! That's what I thought!
Reply With Quote
Reply

Tags
bulk, comments

Thread Tools
Display Modes


Similar Threads
Thread Thread Starter Forum Replies Last Post
Easy way to remove comments in bulk? Remove or bulk reset line breaks. Jazz43 Word 5 02-11-2021 08:36 AM
How to remove reviewer's name from comments and track changes? Timotheus Word 3 10-24-2020 01:57 PM
Easy way to remove comments in bulk? Remove highlighted text when inserting comments Iammuffinman Word 3 01-27-2011 02:02 AM
How would I bulk select and copy highlights and then bulk paste them automatically? copywriterpro Word 0 04-19-2010 05:21 AM

Other Forums: Access Forums

All times are GMT -7. The time now is 07:51 AM.


Powered by vBulletin® Version 3.8.11
Copyright ©2000 - 2024, vBulletin Solutions Inc.
Search Engine Optimisation provided by DragonByte SEO (Lite) - vBulletin Mods & Addons Copyright © 2024 DragonByte Technologies Ltd.
MSOfficeForums.com is not affiliated with Microsoft