problem with deleting empty rows MS Word VBA

[nasserlouis]

Hello;
I have this microsoft Word file i need to :

1_ delete empty rows with this macro
------------------

 
Sub DeleteBlankTableRows()

Dim deleted As Boolean
Dim oRow As Row

deleted = False

On Error Resume Next
ActiveDocument.Tables(1).Select
If Selection.Information(wdWithInTable) = False Then
    MsgBox "No table exists in the document!", vbCritical, "Error"
    Exit Sub
End If

For Each oRow In Selection.Tables(1).Rows
    If oRow Is Nothing Then
        MsgBox "The tool cannot work in this table. This might be because one or more rows have merged cells. If these merged cells are removed, it will probably work.", _
        vbCritical, "Error"
        End
    End If
     If Len(oRow.Cells(2).Range.Text) = 2 Then
   'Or If InStr(oRow.Range.Text, "") > 0 Then
        oRow.Delete
        deleted = True
    End If
Next oRow

If deleted Then
    MsgBox "All Blank lines have been deleted.", vbOKOnly, "Success!"
Else
    MsgBox "No Blank lines containing *To Be Deleted* text can be found.", vbOKOnly, "Failure!"
End If

End Sub

-------------------------
the problem is the macro code delete those (see the picture) rows that i don't want to be deleted



2_ i want to use that macro to delete empty rows for all 100 tables with the same construction.

Thank you

[macropod]

Try:

Sub DeleteEmptyRows()
Application.ScreenUpdating = False
Dim Tbl As Table, r As Long
For Each Tbl In ActiveDocument.Tables
  With Tbl
    For r = .Rows.Count To 1 Step -1
      If .Rows(r).Cells.Count > 1 Then
        If Len(.Cell(r, 2).Range.Text) = 2 Then .Rows(r).Delete
      End If
    Next
  End With
Next
Application.ScreenUpdating = True
End Sub

Note: As coded, the macro processes all tables in the document.

[nasserlouis]

Hi;
your suggestion code it worked a treat, many thanks.