On .Select, Errors: Cant Execute in Break Mode

[ilcaa72]

here is the code, i am using Step through in the debugger, when i get to .Select it says, "Cant Execute in Break Mode" . it actually stills selects the sentence and I can continue but still displays this error msg. I would like to select the sentence, to visually track the changes.

Anyway to fix this issue? thanks

If do_DocVars_Exist = 1 Then
    sentNumb = ActiveDocument.Variables("selNumb").Value
    Set prevSent = doc.Sentences(sentNumb)

    With prevSent
        .Select
        .Font.Size = ActiveDocument.Variables("selSize").Value
        .Font.Color = ActiveDocument.Variables("selColor").Value
        .Font.Name = ActiveDocument.Variables("selName").Value
    End With
End If

[gmayor]

Without the rest of the code, anyone trying to assist is flying blind. I think I understand the concept of what the macro is doing and the following will do that provided the values in the variables are appropriate:

Option Explicit

Sub Macro1()
Dim prevSent As Range
Dim sentNumb As Long
    If do_DocVars_Exist = True Then
        sentNumb = ActiveDocument.Variables("selNumb").Value
        If ActiveDocument.Sentences.Count >= sentNumb Then
            Set prevSent = ActiveDocument.Sentences(sentNumb)
            With prevSent
                .Select
                .Font.Size = ActiveDocument.Variables("selSize").Value
                .Font.Color = ActiveDocument.Variables("selColor").Value
                .Font.Name = ActiveDocument.Variables("selName").Value
            End With
        Else
            MsgBox "There is no sentence number " & sentNumb
        End If
    Else
        MsgBox "The required variables are not present"
    End If
End Sub

Function do_DocVars_Exist() As Boolean
Dim oVar As Variable
Dim iVar As Integer: iVar = 0

    For Each oVar In ActiveDocument.Variables
        Select Case oVar.Name
            Case "selNumb", "selSize", "selColor"
                If IsNumeric(oVar.Value) Then
                    iVar = iVar + 1
                End If
            Case "selName"
                iVar = iVar + 1
        End Select
    Next oVar
    If iVar = 4 Then do_DocVars_Exist = True
End Function

[ilcaa72]

the gmayor

but the only question i had was why does the display a msgbox saying "Cannot Execute in Break Mode" once it executes the line with .Select

the code continues with no problems (meaning there really is not effect to "Cannot execute in Break Mode")

it almost seems like a bug to me. why wouldnt i be able to .Select a sentence? Why would it display this message? why would the code be able to continue without any issues and still .Select the sentence...

thks for the reply