GoTo Cell Reference in wdTable

[Hdata]

Thanks in advance for solving my request: I'm looking for VBA code that would send me to a specific cell within a word table. In other words, when I launch this code a text box will appear where I could insert say (Cell 32,4) then click go and the cursor would end up at that specific cell. Thanks so much. (Office 2013)



Hdata

[macropod]

Going to a cell would only be necessary if you need to select something there, which is usually not necessary when working in VBA. So, perhaps you could explain what you're trying to achieve?

[Hdata]

Yes, I have word tables previously setup with updateable cell formulas. I also have a list of cell references which I would like to GoTo in order to update these formulas.

Essentially you have hit the nail on the head. I want to select the contents of that cell or a range of cells in order to update formulas within that cell or range of cells without updating the entire table.

Thanks for your expertise regarding VBA code. (Hdata)

[gmayor]

You probably want something like

Dim oTable As Table
Dim oCell As Cell
    If ActiveDocument.Tables.Count > 0 Then
        Set oTable = ActiveDocument.Tables(1)    'the first table
        Set oCell = oTable.Cell(1, 1)    'Row 1, Column 1
        oCell.Range.Fields.Update
    End If

[macropod]

Originally Posted by Hdata

Yes, I have word tables previously setup with updateable cell formulas. I also have a list of cell references which I would like to GoTo in order to update these formulas.

You don't need to 'Goto' or 'Select' anything for this. All you need is something like:

Sub Demo()
Application.ScreenUpdating = False
Dim ArrTbls, ArrRows, ArrCols, i As Long
ArrTbls = Array(1, 1, 3, 3, 4, 5)
ArrRows = Array(6, 8, 6, 8, 6, 6)
ArrCols = Array(4, 4, 5, 7, 2, 2)
With ActiveDocument
  For i = 0 To UBound(ArrTbls)
    .Tables(ArrTbls(i)).Cell(ArrRows(i), ArrCols(i)).Range.Fields.Update
  Next
End With
Application.ScreenUpdating = True
End Sub

With this code, you use three arrays, one each for the tables, rows & columns to be updated. Each array contains its respective table index, row index and cell index for the cells you want to update. In the above demo, the first set of array entries points to table 1, row 6 column 4, the second set of array entries points to table 1, row 8 column 4, and so on.

[Hdata]

Thanks Graham

[Hdata]

Thanks Paul