issue with highlight macro word 2010

[jamesnavoy]

Hi guys, I'm looking for help with a simple find and highlight words macro. this macro i was trying out seems to only be able to highlight with the currently active highlighted color, not the replacement color mentioned in the macro so I was wondering why that might be happening? and secondly i would like to do 3 set of the same routine, different colors for different words. how do i ammend this to achieve it please?

Sub ListChange()
Dim r As Range
Dim MyList() As String
Dim i As Long
MyList = Split("challenging,difficult,down by,", ",")
For i = 0 To UBound(MyList())
   Set r = ActiveDocument.Range
      With r.Find
         .Text = MyList(i)
         .Replacement.Highlight = wdGreen
         .Execute Replace:=wdReplaceAll
      End With
Next
End Sub

[gmayor]

Change as follows:

Sub ListChange()
Dim r As Range
Dim MyList() As String
Dim i As Long
    MyList = Split("challenging,difficult,down by,", ",")
    For i = 0 To UBound(MyList())
        Set r = ActiveDocument.Range
        With r.Find
            Do While .Execute(FindText:=MyList(i))
                Select Case i
                    Case Is = 0
                        r.HighlightColorIndex = wdYellow
                    Case Is = 1
                        r.HighlightColorIndex = wdTurquoise
                    Case Else
                        r.HighlightColorIndex = wdGreen
                End Select
                r.Collapse 0
            Loop
        End With
    Next
End Sub

[jamesnavoy]

thanks gmayor, sorted it out and edited for what i needed now. tnx very much for the quick response.