Getting bold Pargraph

[kirkm]

Hi, I'm new to Word VBA but playing around with this

Sub ShowPara()
Stop
    Dim p As Paragraph, pp As String, MyParaNum As Integer
    Dim pp2 As String
    For Each p In ActiveDocument.Paragraphs
        MyParaNumber = MyParaNumber + 1
        pp = p.Range.Text
        If Not p.Range.End Then
            pp2 = p.Range.Next.Paragraphs(1).Range.Text
        End If
    
    Next
End Sub

Don't know if I need MyParaNum there may be another way but it's a count to return to that point in the doc (as needed).


I want to get each next paragraph after any paragraph that is bolded.
Is that possible ?

After finding I want to do some checks on it, then maybe replace it. I think it's p.Range.Text = pp (after pp has been modified).

Thanks.

[macropod]

There is nothing in your code that tests whether a paragraph is bold. Do note that you can use Find/Replace for finding bold content and that testing whether a 'paragraph' is bold presupposes everything, including the paragraph break, is bold (or not). This can be done with or without VBA.

Unless you say what you're trying to achieve, we can't give more specific advice; the solution may or may not require a loop to implement.

[gmayor]

It is not exactly clear what

I want to get each next paragraph after any paragraph that is bolded.

means but if you want to get the next non-bold paragraph after a bold paragraph then:

Sub ShowPara()
Dim oPara As Paragraph, sText As String, oRng As Range
    For Each oPara In ActiveDocument.Paragraphs
        If oPara.Range.Bold = True Then
            If Not oPara.Range.End = ActiveDocument.Range.End Then
                Set oRng = oPara.Range.Next.Paragraphs(1).Range
                If oRng.Bold = False Then
                    sText = oRng.Text
                    oRng.Select
                    MsgBox sText
                End If
            End If
        End If
    Next oPara
lbl_Exit:
    Exit Sub
End Sub

[macropod]

And if either the bold paragraph or the non-bold paragraph is differentiated by a Style, using Find/Replace for finding the Style(s) might be rather more efficient.

[kirkm]

Thank you Paul and Graham (your code works for me).
But when I do stuff with the paragraph, I have to Stop the code and when restarted it goes through those paragraphs a second time.
Can I start it where I want e.g paragraph number 300 ? I could write that into the code each time; it doesn't need to be automatic.

I am working through the document fixing OCR errors manually.

[macropod]

You could just tweak Graham's code a bit, then select the range you want to work with before running the macro:

Sub ShowPara()
Dim oPara As Paragraph, sText As String, oRng As Range
With Selection
    For Each oPara In .Paragraphs
        If oPara.Range.Bold = True Then
            If Not oPara.Range.End = .Paragraphs.Last.Range.End Then
                Set oRng = oPara.Range.Next.Paragraphs(1).Range
                If oRng.Bold = False Then
                    sText = oRng.Text
                    oRng.Select
                    MsgBox sText
                End If
            End If
        End If
    Next oPara
End With
End Sub

[kirkm]

That just ends immediately. Does something need to setup .Paragraphs.Last.Range.End ?

[macropod]

Did you select the range you want to process?

[kirkm]

ah, sorry - no. You mean like Control-A ?

[macropod]

Ctrl-A will select the entire document. Instead of doing that, which is no better than using Graham's original code, you might just select a particular range with the mouse, or position the cursor where you want to start from and use Ctrl-Shift-End to select from there to the end of the document.

[kirkm]

Thanks Paul. Understood. I'm now trying some more advanced methods (using a Form) and seeing what I can make work.

In the line Set oRng = oPara.Range.Next.Paragraphs(1).Range

What does the (1) mean ?

[macropod]

If a range object spans multiple paragraphs, you can change the 1 to 2, 3, etc. to specify which paragraph in the range to work with. With the way oRng is set in the code you're using, you can only use 1. You could also use:
Set oRng = oPara.Range.Next.Paragraphs.First.Range
or:
Set oRng = oPara.Range.Next.Paragraphs.Last.Range