Keeping Table on One Page

[SCMiller]

I'm wanted to keep each table on one page. I'm missing something here. Can someone give me some help?

Sub KeepRowsTogether()
    Dim tbl As Table
    Dim nPara As Long, i As Long
    
    For Each tbl In ActiveDocument.Tables
        nPara = tbl.Range.Paragraphs.Count
        For i = 1 To (nPara - 1)
            tbl.Range.Paragraphs(i).KeepWithNext
        Next i
    Next tbl
End Sub

[macropod]

Hi SCMiller,

You need:
KeepWithNext = True.

However, the code could be greatly simplified:

Sub KeepRowsTogether()
Dim oTbl As Table
For Each oTbl In ActiveDocument.Tables
  oTbl.Range.Paragraphs.KeepWithNext = True
Next oTbl
End Sub

The problem with either approach, though, is that it forces the table to 'keep with next' with the first paragraph following it. What you need is for the last paragraph in each cell on the last row not to have the 'keep with next' attribute:

Sub KeepRowsTogether()
Dim oTbl As Table, oCel As Cell
For Each oTbl In ActiveDocument.Tables
  oTbl.Range.Paragraphs.KeepWithNext = True
  For Each oCel In oTbl.Rows.Last.Range.Cells
    oCel.Range.Paragraphs.Last.KeepWithNext = False
  Next oCel
Next oTbl
End Sub

[SCMiller]

Thanks! I greatly appreciate your help!

[andyroberts1234]

Hello,

I have been trying to run this code however come across the following error:

Runtime error 5991: Cannot access the individual rows of this collection because the table has vertically merged cells.

Is there a way to make it work with tables with merged cells, or if not to do something like 'if table has merged cells then skip the formatting of this table'?

For clarity, this is the code I am running:

Sub ApplyTableAttribute()
'
' ApplyTableAttribute Macro
'
'
Dim oTbl As Table, oCel As Cell
' for each table in the active document
For Each oTbl In ActiveDocument.Tables
'set paragraphs to keep with next
  oTbl.Range.Paragraphs.KeepWithNext = True
  ' for each cell in the last row of the table
  For Each oCel In oTbl.Rows.Last.Range.Cells
  ' 'set the last paragraph to not keep with next
    oCel.Range.Paragraphs.Last.KeepWithNext = False
  Next oCel
Next oTbl
End Sub

Thanks

Andy

[macropod]

Try:

Sub KeepRowsTogether()
Dim oTbl As Table, oCel As Cell
For Each oTbl In ActiveDocument.Tables
  With oTbl
    .Range.Paragraphs.KeepWithNext = True
    If .Uniform = True Then
      For Each oCel In .Rows.Last.Range.Cells
        oCel.Range.Paragraphs.Last.KeepWithNext = False
      Next oCel
    Else
      Set oCel = .Range.Cells(.Range.Cells.Count)
      Do While oCel.ColumnIndex > 1
        oCel.Range.Paragraphs.Last.KeepWithNext = False
        Set oCel = oCel.Previous
      Loop
      oCel.Range.Paragraphs.Last.KeepWithNext = False
    End If
  End With
Next oTbl
End Sub