Programmatically Selecting Files in Word for Windows

[Ajay2506]

Is there a way to write a vba code in word file, which allow users to open a browse option to select and open the files in various folders, where they can select any file to open, then do some operation on them and save it.



Similar work has been performed in this site in Excel, but I want it for word file.
https://msdn.microsoft.com/en-us/lib...ffice.14).aspx

So when we click the macro, it will first ask to select the PDF file, once we click open then it will open that pdf file in word, then we can call other macro, perform some action and then save the file with the .docx extension.

[gmayor]

Bearing in mind that not all PDF format files are editable in Word, and that this only works for Word versions 2013 and later, the following can be used to select and open one

Option Explicit

Sub Macro1()
Dim strFname As String
Dim oDoc As Document
    strFname = BrowseForFile("Select the PDF file to open")
    If strFname = vbNullString Then GoTo lbl_Exit
    Set oDoc = Documents.Open(strFname)
    'do stuff with odoc
lbl_Exit:
    Exit Sub
End Sub

Function BrowseForFile(Optional strTitle As String) As String
'Graham Mayor - http://www.gmayor.com
'strTitle is the title of the dialog box
'Set bExcel value to True to filter the dialog to show Excel files
'The default is to show Word files
Dim fDialog As FileDialog
    On Error GoTo err_handler
    Set fDialog = Application.FileDialog(msoFileDialogFilePicker)
    With fDialog
        .Title = strTitle
        .AllowMultiSelect = False
        .Filters.Clear
        .Filters.Add "Adobe PDF files", "*.pdf"
        .InitialView = msoFileDialogViewList
        If .Show <> -1 Then GoTo err_handler:
        BrowseForFile = fDialog.SelectedItems.Item(1)
    End With
lbl_Exit:
    Exit Function
err_handler:
    BrowseForFile = vbNullString
    Resume lbl_Exit
End Function

[Ajay2506]

Thank you for your help