Error adding row to table

[jeffreybrown]

This macro works fine until it hits a table where there are vertically merged cells in the table. I get an error 5991 "Cannot access individual rowsin this collection because the table has vertically merged cells"



Is is possible to add rows to those tables or do I just need to skip those tables and move on?

Sub Add_Rows_Table()
    Application.ScreenUpdating = False
    Dim Tbl As Table, Rng As Range
    For Each Tbl In ActiveDocument.Tables
        Tbl.Select
        Tbl.Rows.Add BeforeRow:=Selection.Rows(1)
    Next Tbl
    Application.ScreenUpdating = True
End Sub

[gmaxey]

You can add rows until the cows come home but you can't access a single row:

Sub ScratchMacro()
'A basic Word macro coded by Greg Maxey
Dim oTbl As Word.Table
  For Each oTbl In ActiveDocument.Tables
    oTbl.Rows.Add
  Next
lbl_Exit:
  Exit Sub
End Sub

[jeffreybrown]

I'm looking to add a row to the beginning of every table.

This macro just repeats adding a row to one table and that's it, plus it's at the bottom.

The table that is throwing up the error is a table where the first row of the table is merged vertically with cells below.

Let's say the table is 8X5

Cell D1 thru D3 is merged along with G1 thru G4

[macropod]

You could use:

Sub Add_Rows_Table()
    Application.ScreenUpdating = False
    Dim Tbl As Table, Rng As Range
    For Each Tbl In ActiveDocument.Tables
        Tbl.Cell(1, 1).Range.Select
        Selection.InsertRowsAbove 1
    Next Tbl
    Application.ScreenUpdating = True
End Sub

[gmaxey]

Jeffery,

I know what my code does because I wrote it. It would be beneficial if you would clearly state what you want to do in "words" upfront.

You can insert a new row before the first row like this:

Sub ScratchMacro()
'A basic Word macro coded by Greg Maxey
Dim oTbl As Word.Table
  For Each oTbl In ActiveDocument.Tables
    oTbl.Range.Select
    Selection.Collapse wdCollapseStart
    Selection.InsertRowsAbove 1
  Next oTbl
lbl_Exit:
  Exit Sub
End Sub

[jeffreybrown]

Thanks Paul...that does it...