Macro word 2010 to save word file into xml

[michele82]

Hi,
i want to create a macro in word 2010 to save all .doc and .docx files in a folder,
to another folder in .xml format.


Someone can give me some suggestion on how to do?

[gmayor]

The following should do the job. The modified documents will be saved in the named folder at strNewPath (which miust exist).

Sub SaveAsXML()
Dim fDialog As FileDialog
Dim oDoc As Document
Dim strPath As String
Dim strFile As String
Const strNewPath As String = "C:\Path\"
Dim strName As String
    On Error GoTo err_Handler
    Set fDialog = Application.FileDialog(msoFileDialogFolderPicker)
    With fDialog
        .Title = "Select folder and click OK"
        .AllowMultiSelect = False
        .InitialView = msoFileDialogViewList
        If .Show <> -1 Then
            MsgBox "Cancelled By User", , "List Folder Contents"
            GoTo lbl_Exit
        End If
        strPath = fDialog.SelectedItems.Item(1)
        If Right(strPath, 1) <> "\" Then strPath = strPath & "\"
    End With
    If Documents.Count > 0 Then
        Documents.Close SaveChanges:=wdPromptToSaveChanges
    End If
    strFile = Dir$(strPath & "*.doc")
    While strFile <> ""
        Set oDoc = Documents.Open(strPath & strFile)
        strName = Left(oDoc.name, Len(oDoc.name) - InStrRev(oDoc.name, Chr(46))) & ".xml"
        oDoc.SaveAs2 Filename:=strNewPath & strName, FileFormat:=wdFormatXML, AddToRecentFiles:=False
        oDoc.Close 0
        strFile = Dir$()
    Wend
lbl_Exit:
    Exit Sub
err_Handler:
    Err.Clear
    GoTo lbl_Exit
End Sub

[michele82]

Thanks gmayor,
your code does just what i wanted to do, the only thing is that it saves all documents in the folder selected except the last one, why do you think?

[michele82]

If i want to do the same also for the .docx? It's possible?