Delete text within two bookmarks

[dugdugdug]

Assuming I have the following text:

Hello,

"BOOKMARK_START"

What are you doing

'BOOKMARK_END"

Call me

I want to delete the text within two bookmarks in Word to end up with:

Hello,

Call me

I found this code:

Dim pRange
Dim dRange
Dim myrange

pRange = ActiveDocument.Bookmarks("BOOKMARK_START").Range.Start
dRange = ActiveDocument.Bookmarks("BOOKMARK_END").Range.End
Set myrange = ActiveDocument.Range(Start:=pRange, End:=dRange)
myrange.Cut

What happens when the code is run is BOOKMARK_START and BOOKMARK_END point to the same place, (which is BOOKMARK_START), ie:

Hello,

BOOKMARK_START / BOOKMARK_END

Call me

Next time I insert something into BOOKMARK_START (and then try to delete it), it won't recognise BOOKARK_END (because it's the same location as BOOKMARK_START).

How can I get round this?

[Guessed]

Using Bookmarks is quite clumsy because you have little control on where those bookmarks start/end and the 'end' may be in front of the 'start'. Once you have removed the intervening content you will find it difficult to prise the two locations apart again.

A simpler way of defining a location for content is to use a Content Control and write to that.

ActiveDocument.SelectContentControlsByTitle("Info")(1).Range.Text = "Hi Mum"

Note that when you remove all content of that CC, it will display the placeholder text which may or may not suit your purposes. You can either edit the placeholder text or put a single space in the placeholder to avoid this problem.

[gmayor]

Note that when you remove all content of that CC, it will display the placeholder text which may or may not suit your purposes. You can either edit the placeholder text or put a single space in the placeholder to avoid this problem

If you fill the content control with zero width space ChrW(8203) the control will completely disappear, but will still be present to be refilled with something else.

Sub Macro1
    FillCC "MyCCTitle", ChrW(8203), True

End Sub

Public Sub FillCC(strCCTitle As String, strValue As String, bLock As Boolean)
'Graham Mayor - https://www.gmayor.com - Last updated - 03 Sep 2021
Dim oCC As ContentControl
    On Error GoTo lbl_Exit
    For Each oCC In ActiveDocument.ContentControls
        With oCC
            If .Title = strCCTitle Then
                .LockContents = False
                .Range.Text = strValue
                .LockContentControl = True
                .LockContents = bLock
                Exit For
            End If
        End With
    Next oCC
lbl_Exit:
    Set oCC = Nothing
    Exit Sub
End Sub

[dugdugdug]

Thanks for the suggestions.