Check for a horizontal line

NevilleT · #1 01-06-2016, 09:40 PM

I have an application that inserts a horizontal line in a Word document. I want to check if a horizontal line has already been inserted in the prior line. In other words, I don't want to insert a second horizontal line if there is already one there.

I am using this code to check the prior line. It tells me there is an inline shape, but not if it is a line. Can anyone help me establish if the inline shape is a horizontal line.

Selection.MoveUp

If Selection.InlineShapes.Count = 0 Then
Selection.MoveDown

' Create the line
Selection.InlineShapes.AddHorizontalLineStandard

' Line size and alignment
Set shpLine = ThisDocument.InlineShapes(ThisDocument.InlineShape s.Count)
shpLine.HorizontalLineFormat.PercentWidth = 80
shpLine.HorizontalLineFormat.Alignment = wdHorizontalLineAlignRight

End If

gmayor · #2 01-06-2016, 10:04 PM

The following will warn you if there is a hoirizontal line in the current or previous paragraph

Code:

Option Explicit

Sub InsertHorizontalLine()
Dim shpLine As InlineShape
Dim oShape As InlineShape
Dim orng As Range
    Set orng = Selection.Range
    ' Check the previous paragraph
    If Not orng.Start = ActiveDocument.Range.Start Then
        If orng.Paragraphs(1).Previous.Range.InlineShapes.Count > 0 Then
            Set oShape = orng.Paragraphs(1).Previous.Range.InlineShapes(1)
            If oShape.Type = 6 Then
                MsgBox "Line exists in the previous paragraph?"
                GoTo lbl_Exit
            End If
        End If
    End If
    ' Check the current paragraph
    If orng.Paragraphs(1).Range.InlineShapes.Count > 0 Then
        Set oShape = orng.Paragraphs(1).Range.InlineShapes(1)
        If oShape.Type = 6 Then
            MsgBox "Line exists in the current paragraph?"
            GoTo lbl_Exit
        End If
    End If
    ' Create the line
    Set shpLine = orng.InlineShapes.AddHorizontalLineStandard
    ' Line size and alignment
    shpLine.HorizontalLineFormat.PercentWidth = 80
    shpLine.HorizontalLineFormat.Alignment = wdHorizontalLineAlignRight
lbl_Exit:
    Exit Sub
End Sub

NevilleT · #3 01-06-2016, 11:50 PM

Thanks Graham. That looks like it will do the job. I need to do some modifications but the core is great. I have used VBA extensively in Access but have to learn how to do it in Word. Same but different.

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
smart art horizontal line	sgroves20	Word	0	11-05-2014 08:17 AM
a troubling horizontal line	mingming	Word	1	09-14-2014 05:16 AM
unable to delete a horizontal line	jerryny	Word	2	03-31-2013 05:59 PM
How to set month+1 and horizontal line	nightkn8	Word	12	03-25-2013 02:06 PM
Horizontal sawtooth line	JamesT	Word	3	10-29-2011 05:39 PM