Find, select, and replace part of text with bold

[paik1002]

I'd like to find a text in a selection and change only a part of the found text by boldfacing it.

For example, first find the text "hello there" in the present selection (e.g. first page of document), then boldface only "there".

Could it be done?


I am struggling with the following sort of VB code. FYI, wildcards are in use.

Selection.Find.ClearFormatting
Selection.Find.Replacement.Font.Bold = True (??????????)
With Selection.Find
.text = "(hello)*(there)"
.Replacement.text = (???????????)
.Forward = True
.MatchWildcards = True
.Wrap = wdFindStop
.Format = False
.MatchCase = False
.MatchWholeWord = False
.MatchByte = False
.MatchSoundsLike = False
.MatchAllWordForms = False


End With
Selection.Find.Execute Replace:=wdReplaceAll

[macropod]

You could use a macro like:

Sub Demo()
Application.ScreenUpdating = False
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = InputBox("What is the Text to Find")
    .Replacement.Text = ""
    .Forward = True
    .Wrap = wdFindStop
    .Format = False
    .MatchCase = False
    .MatchWholeWord = False
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
    .Execute
  End With
  Do While .Find.Found
    .Words.First.Font.Bold = False
    .Words.Last.Font.Bold = True
    .Collapse wdCollapseEnd
    .Find.Execute
  Loop
End With
Application.ScreenUpdating = True
End Sub

PS: When posting code, please use the code tags, indicated by the # button on the posting menu

[paik1002]

Thank you, but I can't get it to work.

Sub Demo()
    Application.ScreenUpdating = False
 
    With ActiveDocument.Range
      With .Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .text = "(hello)*(there)"
        .Replacement.text = ""
        .Forward = True
      .MatchWildcards = True
        .Wrap = wdFindStop
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
        .Execute
      End With
 
      Do While .Find.found
        Words.First.Font.Bold = False
        Words.Last.Font.Bold = True
        .Collapse wdCollapseEnd
        .Find.Execute
      Loop
    End With
    Application.ScreenUpdating = True
End Sub

I modified my code by incorporating your code into it, but I get a 424 run-time error,

        Words.First.Font.Bold = False

[macropod]

You're missing the period in front of 'Words' (i.e. '.Words').

[paik1002]

I overlooked on that. Thank you. It is working now.