Using VBA to convert AutoCAD into WMF

[Freedom20]

I am trying to write a macro to open an AutoCAD dxf drawing and convert it to wmf and then import into the current Word document. Below is the code that I have written. My comments to the code are in blue.

Sub Convert_dxf()
Dim iRow As Integer
Dim AcadApp As Object
Dim SS 'As AcadSelectionSet Word will not let me declare this as a selection set


On Error Resume Next
Set AcadApp = GetObject(, "AutoCAD.Application")
If Err.Number <> 0 Then
Set AcadApp = CreateObject("AutoCAD.Application")
End If
AcadApp.Visible = True

AcadApp.Documents.Open ("C:\drawing.dxf")

Set SS = AcadApp.ActiveDocument.SelectionSets.Add("SS")
Set SS = Nothing
'SS.AcadApp.SelectAll
AcadApp.ActiveDocument.Export "C:\drawing", "WMF", SS
'at this point AutoCAD waits for me to select items on drawing.
'according to AutoCAD's help if the selection set is Nothing it is supposed to select the entire drawing.

AcadApp.ActiveDocument.Close savechanges:=False
' If AcadApp.Documents.Count = 1 Then
' AcadApp.ActiveDocument.sendcommand "Exit" & vbCr
' is there a way to close AutoCAD without using SendCommand?

' End If
Set AcadApp = Nothing
End Sub

I am open to other methods as long as the produce the same results. I do not want to take a screen shot or similar due to line quality issues.




Thank you in advance for any assistance you can provide.

[macropod]

Originally Posted by Freedom20

Dim SS 'As AcadSelectionSet Word will not let me declare this as a selection set

You could only do that if you were using early binding, but you're using late binding.

Originally Posted by Freedom20

Set SS = AcadApp.ActiveDocument.SelectionSets.Add("SS")
Set SS = Nothing
'SS.AcadApp.SelectAll
AcadApp.ActiveDocument.Export "C:\drawing", "WMF", SS
'at this point AutoCAD waits for me to select items on drawing.
'according to AutoCAD's help if the selection set is Nothing it is supposed to select the entire drawing.

Given that you've already 'Set SS = Nothing', there's nothing to export. You really should leave that line until after you've finished with the object.

Originally Posted by Freedom20

' AcadApp.ActiveDocument.sendcommand "Exit" & vbCr
' is there a way to close AutoCAD without using SendCommand?

That all depends on what methods are available in AutoCAD (e.g. AcadApp.Quit might be a valid method) - it's not really a Word issue. Ordinarily, though, one would also expect the open file to be closed before you quit the application.

[Freedom20]

Originally Posted by macropod

You could only do that if you were using early binding, but you're using late binding.

I am not familiar with early vs. late binding. I am self taught in VBA and have not seen those terms before. How would I set this up with early binding?

[macropod]

Here's an article about Early and Late Binding: https://support.microsoft.com/en-us/kb/245115.

An essential distinction between early binding and late binding is that, to use early binding, you must set a reference to the application (in this case AutoCAD) in the VBE via Tools|References. Once you do that, though, you can use all of the application's methods, procedures and properties much more easily than you can using late binding.

Using early binding, your code might become:

Sub Convert_dxf()
Dim AcadApp As AutoCAD.Application
Dim AcadDoc As AutoCAD.Document
Dim SS As AutoCAD.AcadSelectionSet
Set AcadApp = New AutoCAD.Application
With AcadApp
  .Visible = False
  Set AcadDoc = .Documents.Open("C:\drawing.dxf")
  With AcadDoc
    Set SS = .SelectionSets("SS")
    .Export "C:\drawing.wmf", "WMF", SS
    .Close SaveChanges:=False
  End With
  .Quit
End With
Set SS = Nothing: Set AcadDoc = Nothing: Set AcadApp = Nothing
End Sub

Note: I don't have AutoCAD, so I don't know what it's VB object model looks like or what methods, procedures and properties are available. Accordingly, you'll have to do your own work on that front. For testing purposes, you'll also want to comment-out the line:
.Visible = False
otherwise you could end up with a plethora of hidden and orphaned AutoCAD sessions running in the background.

[Freedom20]

Thank you for the reply. However, I was not able to get the code to run.

Originally Posted by macropod

Using early binding, your code might become:

Sub Convert_dxf()
Dim AcadApp As AutoCAD.Application
Dim AcadDoc As AutoCAD.Document
Dim SS As AutoCAD.AcadSelectionSet
Set AcadApp = New AutoCAD.Application
With AcadApp
  .Visible = False
  Set AcadDoc = .Documents.Open("C:\drawing.dxf")
  With AcadDoc
    Set SS = .SelectionSets("SS")
    .Export "C:\drawing.wmf", "WMF", SS
    .Close SaveChanges:=False
  End With
  .Quit
End With
Set SS = Nothing: Set AcadDoc = Nothing: Set AcadApp = Nothing
End Sub

The code was getting hung up on the following line

Set AcadDoc = .Documents.Open("C:\drawing.dxf")

I found another solution. I placed the export code into AutoCAD and called it from Word.

For anyone who might need it, the solution I found is below.

Code in Word:

Sub Convert_dxf()
Dim AcadApp As Object
        
    On Error Resume Next
    Set AcadApp = GetObject(, "AutoCAD.Application")
    If Err.Number <> 0 Then
        Set AcadApp = CreateObject("AutoCAD.Application")
    End If
    AcadApp.Visible = False
        
    AcadApp.Documents.Open ("C:\drawing.dxf")
    AcadApp.RunMacro "Convert_drawing"
     AcadApp.ActiveDocument.Close savechanges:=False
    If AcadApp.Documents.Count = 1 Then
        AcadApp.ActiveDocument.Close savechanges:=False
        AcadApp.Quit
    End If
    Set AcadApp = Nothing
End Sub

The code in AutoCAD:

Sub Convert_drawing()
Dim SS As AcadSelectionSet
 
Set SS = ActiveDocument.SelectionSets.Add("SSet")
SS.Select acSelectionSetAll
ActiveDocument.Export "C:\drawing", "WMF", SS
Set SS = Nothing
 
End Sub

Note that if AutoCAD is left running, you might get an error stating that the selectionset already exists.