Extracting lines containing specific word.

[S.Allen]

Hello.



I quite desperately need some assisstance. I am trying to collate information together to be used as supporting evidence for a visa application.

The evidence is essentially just copied and pasted to word facebook messages (need to establish a relationship has existed). There are 2.5 thousand pages of messages.

What I want to do is get rid of the message part, and just extract the line which contains the sender and time/date info. For example, a message appears like this:

Seb AllenThursday, 26 March 2015 at 16:13 UTC

Gracias!!


Sender, time and date info on one line, followed by the message. My thoughts are that it is possible to use the UTC to extract the line. So any line containing the phrase 'UTC' could be extracted? I have basic VBA knowledge, but I'm super rusty.

Any help is greatly appreciated.

[gmayor]

It seems fairly straightforward. How about:

Sub ExtractText()
'Seb AllenThursday, 26 March 2015 at 16:13 UTC
Dim oSource As Document
Dim oTarget As Document
Dim oRng As Range
    Set oSource = ActiveDocument
    'Create a document to hold the extracts
    Set oTarget = Documents.Add
    'replace line breaks with paragraph breaks
    Set oRng = oSource.Range
    oRng.Text = Replace(oRng.Text, Chr(11), Chr(13))
    With oRng.Find
        'Find the times
        Do While .Execute(FindText:="at [0-9]{2}:[0-9]{2} UTC", _
                          MatchWildcards:=True)
            'Copy the paragraph containing the found time to the new document
            oTarget.Range.InsertAfter oRng.Paragraphs(1).Range.Text
            oRng.Collapse 0
            DoEvents
        Loop
    End With
lbl_Exit:
    Exit Sub
End Sub