automate macro for merged document (after merge)

[eibst]

Hi Community!



I got a problem. I'm printing a document from our companies crm with mailmerge. Now the problem is that objects have different attributes (different size) and so sometimes the table gehts filled nearly entirely sometimes its nearly empty ! So I looked for a makro to clean the table and found one working for me :

  Dim myTable As Table
Dim myRow As Row
Dim myCell As Cell
Dim myRange As Range
Dim IsEmpty As Boolean

For Each myTable In ActiveDocument.Tables
For Each myRow In myTable.Rows
IsEmpty = True
For Each myCell In myRow.Cells
Set myRange = myCell.Range
myRange.MoveEnd Unit:=wdCharacter, Count:=-1
If myRange.Text <> "" Then IsEmpty = False
Next myCell
If IsEmpty Then myRow.Delete
Next myRow
Next myTable

The thing is I want it to run automatically on the merged document which does unfortunately not work with autoOpen(), AutoExec() and so on.
Is there any possibilty that it automatically will be executed on the merged document!

I'm looking forward to your answers

regards
Stefan

PS: Sorry for my bad english

[macropod]

If your mailmerge is being run through code, you could use that code to call the cleanup routine. There are more efficient means of doing that, though.

The following code will delete all blank rows (except for those with vertically merged cells) in all tables in the active document.

Sub DelBlankRows()
Application.ScreenUpdating = False
Dim i As Long, j As Long
With ActiveDocument
  For i = .Tables.Count To 1 Step -1
    With .Tables(i)
      For j = .Rows.Count To 1 Step -1
        On Error Resume Next 'skip vertically merged cells
        With .Rows(j)
          If Trim(Replace(Replace(.Range.Text, Chr(13) & Chr(7), ""), Chr(160), "")) = "" Then .Delete
        End With
        On Error GoTo 0
      Next
    End With
  Next
End With
Application.ScreenUpdating = True
End Sub