SaveAs docm file from template

[ptmuldoon]

I have word macro enabled template file that that users use to create a new document from.



Is there a way to have the file default to be saved as a docm file for just that template file when the initially save their new document? I still want all other files to be saved under a normal docx format.

I starting to search google, but thinking/guessing maybe something with a BeforeSave Event?

[gmaxey]

Yes you should be able to use the BeforeSave event. See if this gets you started:

Option Explicit
Private WithEvents m_oThisApp As Application
Private Sub Class_Initialize()
  'Syncronize class with application.
  Set m_oThisApp = Word.Application
lbl_Exit:
  Exit Sub
End Sub
Private Sub m_oThisApp_DocumentBeforeSave(ByVal Doc As Document, SaveAsUI As Boolean, Cancel As Boolean)
Dim oDialog As Dialog
  If ActiveDocument.AttachedTemplate = ThisDocument.AttachedTemplate Then
    Cancel = True
    Set oDialog = Dialogs(wdDialogFileSaveAs)
    With oDialog
      .Format = 13
      .Show
    End With
  End If
End Sub

[ptmuldoon]

I think the code you provide makes sense, but I couldn't seem to get it work last night. I think I need to place the beginning WithEvent in a Class Module, and the rest either in ThisDocument or normal module.

I need to get some real work here done this morning, but will give it a 2nd try again later today.

And all of this does belong in the word macro template dotm file correct?

[gmaxey]

Put this code in a standard module of your template:

Option Explicit
Private m_ThisApp As clsThisApp
Sub AutoNew()
  InitiateAppClass
lbl_Exit:
  Exit Sub
End Sub
Sub AutoOpen()
  InitiateAppClass
lbl_Exit:
  Exit Sub
End Sub
Sub InitiateAppClass()
  Set m_ThisApp = New clsThisApp
End Sub

Put the previous code in a class module that you have named clsThisApp

[ptmuldoon]

A HUGE Thanks for helping with that.

I'm going to now try and modify that same information to work with an Excel file. Similar situation. Saving a new excel file off an an excel macro template to default to xlsm vs xlsx.

[ptmuldoon]

Think I hit a small snag?

I want the document to only force the saving as a .docm file on the initial save as. The orginal code seemed to want to force a SaveAs during each save of the document as..

So I modded the If Statement to check if the SaveAsUI is true, and that seems to work, but......

What is strange is that you edit the document, then attempt to close the file and chose not to save, vba throws an error; runtime error 4248.

It appears to happen only if the document is open by itself as Word attempts to close the application and gives the error. If there are other word files open, it does not give the error.

I think I just need to tweak the If Statement some

Private Sub m_ThisApp_DocumentBeforeSave(ByVal Doc As Document, SaveAsUI As Boolean, Cancel As Boolean)
Dim oDialog As Dialog
  If SaveAsUI = True And ActiveDocument.AttachedTemplate = ThisDocument.AttachedTemplate Then
    Cancel = True
    Set oDialog = Dialogs(wdDialogFileSaveAs)
    With oDialog
      .Format = 13
      .Show
    End With
  End If
    
End Sub

[gmaxey]

Try this. I also think the Cancel may have been in the wrong place:

Private Sub m_oThisApp_DocumentBeforeSave(ByVal Doc As Document, SaveAsUI As Boolean, Cancel As Boolean)
Dim oDialog As Dialog
  If ActiveDocument.FullName = ThisDocument.FullName Then Exit Sub
  If ActiveDocument.Path <> vbNullString Then Exit Sub
  If ActiveDocument.AttachedTemplate = ThisDocument.AttachedTemplate Then
    Set oDialog = Dialogs(wdDialogFileSaveAs)
    With oDialog
      .Format = 13
      .Show
    End With
    'I had the cancel in the wrong place. Suppress the normal dialog.
    Cancel = True
  End If
End Sub

[ptmuldoon]

Greg,

Thanks again!! I just to trying out the new code, and things work as they should.

Problem solved!