Losing formatting using .Text to replace

[treva31]

Hi,



I have this little sub that removes leading and trailing spaces from text in cells of all my tables.

It works great but it turns any coloured text to black.

Is there a way to keep the formatting?

Thanks.

Sub RemoveSpaces() 
    Dim oRng As Range 
    Dim oTable As Table 
    Dim acell As Cell 
    For Each oTable In ActiveDocument.Tables 
        With oTable 
            For Each acell In oTable.Range.Cells 
                Set oRng = acell.Range 
                oRng.End = oRng.End - 1 
                oRng.Text = Trim(oRng.Text) 
            Next acell 
        End With 
    Next oTable 
End Sub

[macropod]

Try:

Sub RemoveSpaces()
    Dim oTable As Table, acell As Cell, oRng As Range
    For Each oTable In ActiveDocument.Tables
        With oTable
            For Each acell In oTable.Range.Cells
                Set oRng = acell.Range
                With oRng
                  .End = .End - 1
                  While .Characters.Last = " "
                    .Characters.Last = ""
                  Wend
                  While .Characters.First = " "
                    .Characters.First = ""
                  Wend
                End With
            Next acell
        End With
    Next oTable
End Sub

PS: When posting code, please use the code tags. They're on the 'Go Advanced' tab at the bottom of this screen. Your post tried to replicate them as <CODE></CODE>, whereas the tags here use [ and ] instead of < and >.

[treva31]

Thats perfect thank you!

Yea sorry the code button doesnt seem to be working for me.