Insert input box into macro to allow user to choose multiple text entries

[Hoxton118]

Please could you explain how I could include code which would allow TargetList below to be populated from an input box rather than manually editing the macro. A very simple box along the lines of "Please enter text:".



It's an array so it would be good to give the user the chance to enter more than one item: so that entering "Cats, Dogs" would return Cats or Dogs.

Many thanks

'Sub CopyParas
Dim range As range
Dim i As Long
Dim TargetList
TargetList = Array("Cats", "Dogs") ' put list of terms to find here, in quotation marks, separated by commas
For i = 0 To UBound(TargetList)
Selection.Find.ClearFormatting
With Selection.Find
.Text = TargetList(i)
.Forward = True
.Wrap = wdFindStop
.Format = False
.MatchCase = False
.MatchWholeWord = False
.MatchWildcards = False
.MatchSoundsLike = False
.MatchAllWordForms = False
End With
Do While Selection.Find.Execute
Selection.StartOf Unit:=wdParagraph
Selection.MoveEnd Unit:=wdParagraph
sBigString = sBigString + Selection.Text
Selection.MoveStart Unit:=wdParagraph
Loop
Next
Documents.Add DocumentType:=wdNewBlankDocument
Selection.InsertAfter (sBigString)
End Sub

[macropod]

Basically:

Dim TargetList, i As Long
TargetList = InputBox("Put list of terms to find here, separated by commas")
For i = 0 To UBound(Split(TargetList, ","))
  MsgBox Split(TargetList, ",")(i)
Next

[Hoxton118]

Many thanks. I've tried to insert the code as follows (and lots of other ways too) but cannot make it work. Please advise where I've made an error. Thanks.

Sub CopyParas()
'
' CopyParas Macro
'
Dim range As range
Dim TargetList, i As Long
TargetList = InputBox("Put list of terms to find here, separated by commas")
For i = 0 To UBound(Split(TargetList, ","))
  MsgBox Split(TargetList, ",")(i)
Next
For i = 0 To UBound(TargetList)
Selection.Find.ClearFormatting
With Selection.Find
.Text = TargetList(i)
.Forward = True
.Wrap = wdFindStop
.Format = False
.MatchCase = False
.MatchWholeWord = False
.MatchWildcards = False
.MatchSoundsLike = False
.MatchAllWordForms = False
End With
Do While Selection.Find.Execute
Selection.StartOf Unit:=wdParagraph
Selection.MoveEnd Unit:=wdParagraph
sBigString = sBigString + Selection.Text
Selection.MoveStart Unit:=wdParagraph
Loop
Next
Documents.Add DocumentType:=wdNewBlankDocument
Selection.InsertAfter (sBigString)
End Sub

[macropod]

You haven't integrated the code I gave you with the rest of your code - all you've done is add it to the module.

Try:

Sub CopyParas()
Dim TargetList, i As Long, sBigString As String, Doc As Document
TargetList = InputBox("Put list of terms to find here, separated by commas")
For i = 0 To UBound(Split(TargetList, ","))
  With ActiveDocument.Range
    With .Find
      .ClearFormatting
      .Text = "[!^13]@" & Split(TargetList, ",")(i) & "*^13"
      .Forward = True
      .Wrap = wdFindStop
      .Format = False
      .MatchWildcards = True
      .Execute
    End With
    Do While .Find.Found
      sBigString = sBigString & .Text
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
Next
Set Doc = Documents.Add(DocumentType:=wdNewBlankDocument)
Doc.Range.Text = sBigString
Set Doc = Nothing
End Sub

Although my implementation differs, the principle is the same.

[Hoxton118]

Many thanks for your reply, and sorry I did not know how to include this. Your code works but unfortunately the PC hangs on some searches and fails to return results on others (just shows a blank page). Perhaps this is because of lack of capacity in my PC, but I just wondered if the code could be amended in some way to speed it up? Thanks.

[macropod]

The code already runs about as fast as is possible - and much faster than your original code. If you have a large document and many terms to find, it's quite reasonable that it may take some time to finish processing.

As for skipping some results, that's probably because you've inserted spaces between the terms; only the commas should be inserted (e.g. dog,cat,mouse not dog, cat, mouse), otherwise the spaces are treated as part of the Find criteria.

[Hoxton118]

Many thanks.