Need Help with Below Code

[rsrasc]

I need some help with the below code. I would like to automate this macro to change numbers with the following format:

0001 to 1.
0002 to 2.

0750 to 750.

Up to maybe 0999

Thanks!!!!


Sub ConvertingNumbers()
'
' ConvertingNumbers Macro
'
'
Selection.Find.ClearFormatting
Selection.Find.Replacement.ClearFormatting
With Selection.Find
.Text = "0001"
.Replacement.Text = "1."
.Forward = True
.Wrap = wdFindContinue
.Format = False
.MatchCase = False
.MatchWholeWord = False
.MatchWildcards = False
.MatchSoundsLike = False


.MatchAllWordForms = False
End With
Selection.Find.Execute Replace:=wdReplaceAll
With Selection.Find
.Text = "0002"
.Replacement.Text = "2."
.Forward = True
.Wrap = wdFindContinue
.Format = False
.MatchCase = False
.MatchWholeWord = False
.MatchWildcards = False
.MatchSoundsLike = False
.MatchAllWordForms = False
End With
Selection.Find.Execute Replace:=wdReplaceAll

End Sub

[macropod]

You don't need a macro. You can use a wildcard Find/Replace, where:
Find = ([!1-9])[0]{1,}([0-9]{1,})
Replace = \1\2
Of course, you could encode that in a macro like the one I provided yesterday.

[rsrasc]

My preference would be to encode in a macro because I need it for approximately 60 documents that I'm editing.

Anyway, I tested but doesn't work. Would you please show me what I did wrong?

Thanks in advance!!
Cheers!

Sub Demo2()
Application.ScreenUpdating = False
With ActiveDocument.Range
  .InsertBefore " "
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Forward = True
    .Wrap = wdFindContinue
    .Format = False
    .MatchWildcards = True
    .Text = ".([0-9]{1,3}.)"
    .Replacement.Text = ". \1"
    .Execute Replace:=wdReplaceAll
    .Text = " ([a-e].)"
    .Replacement.Text = "^p\1"
    .Execute Replace:=wdReplaceAll
    .Replacement.Style = "Strong"
    .Text = " ([!1-9])[0]{1,}([0-9]{1,})"
    .Execute Replace:=wdReplaceAll
  End With
  .Characters.First.Delete
End With
Application.ScreenUpdating = True
End Sub

[macropod]

Well, apart from the fact you deleted an existing expression in that macro, you added a space to the start of the new Find expression, omitted a new Replace expression, which means the preceding character would be deleted and a paragraph inserted in its place and, by putting it after the code that applies the 'Strong' Style, would turn the replaced output bold. Try:

Sub Demo()
Application.ScreenUpdating = False
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Forward = True
    .Wrap = wdFindContinue
    .Format = False
    .MatchWildcards = True
    .Text = "([!1-9])[0]{1,}([0-9]{1,})"
    .Replacement.Text = "\1\2"
    .Execute Replace:=wdReplaceAll
  End With
End With
Application.ScreenUpdating = True
End Sub

or, to integrate it into yesterday's macro:

Sub Demo()
Application.ScreenUpdating = False
With ActiveDocument.Range
  .InsertBefore " "
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Forward = True
    .Wrap = wdFindContinue
    .Format = False
    .MatchWildcards = True
    .Text = "([!1-9])[0]{1,}([0-9]{1,})"
    .Replacement.Text = "\1\2"
    .Execute Replace:=wdReplaceAll
    .Text = ".([0-9]{1,3}.)"
    .Replacement.Text = ". \1"
    .Execute Replace:=wdReplaceAll
    .Text = " ([a-e].)"
    .Replacement.Text = "^p\1"
    .Execute Replace:=wdReplaceAll
    .Replacement.Style = "Strong"
    .Text = " ([0-9]{1,3}.)"
    .Execute Replace:=wdReplaceAll
  End With
  .Characters.First.Delete
End With
Application.ScreenUpdating = True
End Sub

PS: When posting code, please use the code tags. They're on the 'Go Advanced' tab.

[rsrasc]

The code is working as intented.

Thank you for your support.

[rsrasc]

Hello Macropod

Even when this thread has been solved, I would like to ask you for two things:

1. Would it be possible to modify the code so I could have more spaces between the questions--probably about six or seven spaces (between letter d and the next question)?

2. I was looking for the "Go Advanced" tab and couldn't find it.--I know, I know- I searched for but I'm not that lucky!!

Thanks anyway for your support!

[macropod]

Originally Posted by rsrasc

1. Would it be possible to modify the code so I could have more spaces between the questions--probably about six or seven spaces (between letter d and the next question)?

The spacing should be handled via Style definitions, with the appropriate before/after paragraph spacing, not by inserting empty paragraphs.

2. I was looking for the "Go Advanced" tab and couldn't find it.--I know, I know- I searched for but I'm not that lucky!!

Try scrolling the reply window down...