Count Number of Pages in Document with Footnotes

[d4okeefe]

I need a macro that will count the number of pages in a word document in which footnotes appear?

Thanks

[macropod]

Finding which pages contain footnote references is easy enough, but finding pages where the footnote from a previous page has overflowed onto it is more problematic.

For the former, try:

Sub FindFootnotePages()
Dim i As Long, Rng As Range, j As Long, k As Long, StrPages As String
With ActiveDocument
  If .ComputeStatistics(wdStatisticPages) > .Footnotes.Count Then
    For i = 1 To .Footnotes.Count
      If .Footnotes(i).Range.Information(wdActiveEndPageNumber) > k Then
        k = .Footnotes(i).Range.Information(wdActiveEndPageNumber)
        j = j + 1
        StrPages = StrPages & k & " "
      End If
    Next
  Else
    For i = 1 To .ComputeStatistics(wdStatisticPages)
      Set Rng = ActiveDocument.GoTo(What:=wdGoToPage, Name:=i)
      Set Rng = Rng.GoTo(What:=wdGoToBookmark, Name:="\page")
      If Rng.Footnotes.Count > 0 Then
        j = j + 1
        StrPages = StrPages & i & " "
      End If
    Next
  End If
  If j <> 0 Then
    StrPages = " references, on pages: " & vbCr & Replace(Trim(StrPages), " ", ", ") & "."
  Else
    StrPages = "s."
  End If
  MsgBox "The document: " & .Name & " contains " & j & " footnote" & StrPages
End With
Set Rng = Nothing
End Sub

For some code to get you started with the latter, see:
http://www.vbaexpress.com/forum/show...l=1#post291194

[d4okeefe]

That's great. Thanks.

[d4okeefe]

Any ideas for how to solve the problem of counting footnotes that fall to a subsequent page? Is there a way to identify how many times the Continuation Notice is used in a document? Or, a way to count the number of times the footnote separator is used?

Thanks again. I always get great answers on this site.

[macropod]

Originally Posted by d4okeefe

Any ideas for how to solve the problem of counting footnotes that fall to a subsequent page?

As indicated in my previous reply, there's some code for that in the link. As I'm travelling at the moment, I'm not in a position to personalize that code.

Originally Posted by d4okeefe

Is there a way to identify how many times the Continuation Notice is used in a document? Or, a way to count the number of times the footnote separator is used?

Possibly, but the code I provided already returns the same count as you'd get for the latter.

[d4okeefe]

Here is the solution I came to. All of the documents I analyze use separators when producing footnotes. The macro checks each page for separator stories and adds the result. Thanks again for your help.

  Dim aPage As Page
  Dim j As Long, k As Long, l As Long, m As Long, x As Long, y As Long
  j = ActiveDocument.ComputeStatistics(wdStatisticPages) 'Total Page Count
  k = 0 'keeps track of current page being analyzed
  l = 0 'counts Separator Story
  m = 0 'counts Continuation Separator Story
  For Each aPage In ActiveDocument.ActiveWindow.ActivePane.Pages
    k = k + 1
    x = aPage.Rectangles.count 'counts Rectangles on each Page
    For y = 1 To x 'cycles through Rectangles on each Page
      If aPage.Rectangles.Item(y).RectangleType = wdTextRectangle Then
        If aPage.Rectangles.Item(y).Range.StoryType = wdFootnoteSeparatorStory Then
          l = l + 1
        End If
        If aPage.Rectangles.Item(y).Range.StoryType = wdFootnoteContinuationSeparatorStory Then
          m = m + 1
        End If
      End If
    Next
  Next
  Debug.Print l + m