Check box values to text

[wpryan]

Hi All,


I'm trying to automate a training certificate by adding a user form in VBA to populate the variables in the document. In it, I have check boxes indicating which course(s) were taken. I'd like to include some code which loops through the items to populate the document. Output is going to a referenced bookmark in the document. Not sure how to approach it. Any help is appreciated.

[gmaxey]

Private Sub CommandButton1_Click()
Dim oCtr As Control
Dim oRng As Word.Range
  For Each oCtr In Me.Controls
    Select Case TypeName(oCtr)
      Case "CheckBox"
        Select Case oCtr.Name
          Case "CheckBox1"
            If Controls(oCtr.Name).Value = True Then
              Set oRng = ActiveDocument.Bookmarks("bmCB1").Range
              oRng.Text = "CheckBox1 is Checked"
              ActiveDocument.Bookmarks.Add "bmCB1", oRng
            End If
        End Select
      Case "TextBox"
        
      Case "ComboBox"
        
      Case "ListBox"
        
    End Select
  Next oCtr
  Unload Me
End Sub

[wpryan]

Thanks for the response, but I guess I'm not getting it. I copied and pasted into the Click command, and changed some of the terminology to match what's in my document. Not working. Here's what I changed (in red):

Dim oCtr As Control
Dim oRng As Word.Range
  For Each oCtr In Me.Controls
    Select Case TypeName(oCtr)
      Case "Checkbox"
        Select Case oCtr.Name
          Case "ckLasik"
            If Controls(oCtr.Name).Value = True Then
              Set oRng = ActiveDocument.Bookmarks("bmCourse").Range
              oRng.Text = "CheckBox1 is Checked"
              ActiveDocument.Bookmarks.Add "bmCourse", oRng
            End If
        End Select
        
    End Select
  Next oCtr

Of course I have 8 other "cases", for which I should repeat the code, right?:

Case "Checkbox"
        Select Case oCtr.Name
          Case "ckLasik"
            If Controls(oCtr.Name).Value = True Then
              Set oRng = ActiveDocument.Bookmarks("bmCourse").Range
              oRng.Text = "CheckBox1 is Checked"
              ActiveDocument.Bookmarks.Add "bmCourse", oRng
            End If

[gmaxey]

Is your checkbox named ckLasik and is your bookmark named bmCourse? Put a stop statement in the code and execute it. When you reach the stop, step through using the F8 key and see if you can determine what is not working:

Dim oCtr As Control
Dim oRng As Word.Range
  For Each oCtr In Me.Controls
    Select Case TypeName(oCtr)
      Stop 'Added stop statement.
      Case "Checkbox"
        Select Case oCtr.Name
          Case "ckLasik"
            If Controls(oCtr.Name).Value = True Then
              Set oRng = ActiveDocument.Bookmarks("bmCourse").Range
              oRng.Text = "CheckBox1 is Checked"
              ActiveDocument.Bookmarks.Add "bmCourse", oRng
            End If
        End Select
        
    End Select
  Next oCtr

[wpryan]

If I scroll through the code, hovering my mouse over the statement

If Controls(oCtr.Name).Value

I see that the different elements are being identified by the code, however there is no transfer of text as I would expect.
The items ckLasik is a check box, and bmCourse is a bookmark.

[gmaxey]

When you "step" through the code using the F8 key, is the:
oRng.Text = "Checkbox 1 is checked"
line of code being executed?

[wpryan]

No, the oRng.Text line is not firing.

[gmaxey]

You will need to figure out what lines are firing and what lines aren't then figure out why. For example, if that line isn't firing then the value of the checkbox my be False (e.g., unchecked).

[wpryan]

Got it, it was a syntax error on my part. This gets me about halfway there... What I wanted, in the end, is for every check box selected, then the book mark would have a concatenated value of those items (e.g, "CheckBox 1 is Checked, Checkbox2 is Checked" etc.)

[gmaxey]

Private Sub CommandButton1_Click()
Dim oCtr As Control
Dim strComposite As String
  For Each oCtr In Me.Controls
    Select Case TypeName(oCtr)
      Case "CheckBox"
        If oCtr.Value = True Then
          If strComposite = vbNullString Then
            strComposite = oCtr.Name & " is checked"
          Else
            strComposite = strComposite & ", " & oCtr.Name & " is checked"
          End If
        End If
      End Select
  Next oCtr
  'Replace this statement with code that writes the string variable to your bookmark.
  MsgBox strComposite
End Sub

[wpryan]

Thanks a lot, you're amazing. With some massaging I got it working. Last question... if I have the document open, and the bookmark is already populated, is it possible to clear the existing data? I tried this code, but it's not working:

If strComposite <> "" Then
ActiveDocument.Bookmarks("Course").Range.Text = strComposite
Else
ActiveDocument.Bookmarks("Course").Range.Text = ""
End If

[gmaxey]

I'm not sure what you are trying to do exactly, however if you use the following method you will always write the string to the bookmark regardless if the string is null or not. Doing so always destroys and recreates the bookmark:

Sub ScratchMacro()
'A basic Word macro coded by Greg Maxey
Dim oRng As Word.Range
Dim strSomething As String
  Set oRng = ActiveDocument.Bookmarks("bmBookmarkName").Range
  oRng.Text = strSomething
  ActiveDocument.Bookmarks.Add "bmBookmarkName", oRng
End Sub