Loop action in Word until not found

[kilburfi]

I have recorded a macro in Word which looks for a '?' and replaces that and everything after it (till the end of the line) with just a pargraph control (to move down to the next line). I have many occurences of ? and various text at the end of each line so have to run the macro as many times as the text exists. The text after the ? is not consistent so I can't just do a find and replace. My current code (from the Macro) which I want to loop is:

Selection.Find.ClearFormatting
With Selection.Find
.Text = "?"
.Replacement.Text = ""
.Forward = True
.Wrap = wdFindContinue
.Format = False
.MatchCase = False
.MatchWholeWord = False
.MatchWildcards = False
.MatchSoundsLike = False
.MatchAllWordForms = False
End With
Selection.Find.Execute
Selection.EndKey Unit:=wdLine, Extend:=wdExtend


Selection.Delete Unit:=wdCharacter, Count:=1

Selection.TypeParagraph

[gmaxey]

Sub ScratchMacro()
'A basic Word macro coded by Greg Maxey
Dim oRng As Word.Range
 Set oRng = ActiveDocument.Range
 With oRng.Find
   .ClearFormatting
   .Text = "\?*^13"
   .Replacement.Text = ""
   .Forward = True
   .Wrap = wdFindContinue
   .Format = False
   .MatchCase = False
   .MatchWholeWord = False
   .MatchWildcards = True
   .MatchSoundsLike = False
   .MatchAllWordForms = False
   While .Execute
     oRng.MoveEnd wdCharacter, -1
     oRng.Delete
    Wend
 End With
End Sub

[kilburfi]

Greg - thanks this code works a treat. I have to admit I was nearly there whilst waiting for a response but it took me a while (very VBA rusty)!