Start of Document Code Problem

[norgro]

I am writing code to highlight "ance" in a Word document. In Braille, there is a contraction for "ance" (and other combinations of letters). My macro seems to work provinding the document does not start with "ance".

It would be appreciated if someone could tell me how to include the "if the document does not start with "ance" condition.



I am attaching the code.

Sub HighlightAnceIfNotStartOfWord() 
    Set oRng = ActiveDocument.Range 
     ' Search document for specified text and highlight text.
    With oRng.Find 
        .Text = "ance" 
         '
         ' .Highlight - colour - yellow if previous character if alphabetic character - otherwise turquoise.
        .Wrap = wdFindStop 'stops at the end of the document
        While .Execute 
             ' MsgBox (oRng.Characters.First.Previous)
            If (Asc(oRng.Characters.First.Previous) >= 65 And Asc(oRng.Characters.First.Previous) <= 90) _ 
            Or (Asc(oRng.Characters.First.Previous) >= 97 And Asc(oRng.Characters.First.Previous) <= 122) _ 
            Then 
                oRng.HighlightColorIndex = wdYellow 
            Else: oRng.HighlightColorIndex = wdTurquoise 
            End If 
        Wend 
    End With 
End Sub

[macropod]

Try the following:

Sub HighlightAnceIfNotStartOfWord()
' Search document for specified text and highlight text.
With ActiveDocument.Range
    With .Find
        .Text = "ance"
         ' .Highlight - colour - yellow if previous character if alphabetic character - otherwise turquoise.
        .Wrap = wdFindStop 'stops at the end of the document
        .Execute
    End With
    Do While .Find.Found
        If .Characters.First.Previous Like "[A-Za-z]" Then
            .HighlightColorIndex = wdYellow
        Else
            .HighlightColorIndex = wdTurquoise
        End If
        .Collapse wdCollapseEnd
        .Find.Execute
    Loop
End With
End Sub

PS: When posting code, please use the code tags. They're on the 'Go Advanced' tab.

[norgro]

Sincere thanks Paul. I really appreciate your help.

What a great forum this is!

Norman