Round off the number

[ubns]

Hi,



If we have table of figures in word lets say - 100 items with the unit price.

If we want to round off the number on maths principle i.e. if more than .5 it increase the number round off for example 12.6 will 13. and if less than .5 it will assume its lower value i.e. 12.4 to 12.

I want this on selected table only. Is there a way we can do this.

Regards

Umesh Banga

[macropod]

All cells, cells in a particular column/row?

[ubns]

all cells in the selected table.

[macropod]

In that case, you could use code like:

Sub FormatNumbers()
Dim Rng As Range, Tbl As Table, oCll As Cell, StrFmt As String
With Selection
  If .Information(wdWithInTable) = True Then
    For Each oCll In .Tables(1).Range.Cells
      Set Rng = oCll.Range
      Rng.End = Rng.End - 1
      If IsNumeric(Rng.Text) Then
        If Left(Rng.Text, 1) Like "[$€£¥]" Then
          StrFmt = Left(Rng.Text, 1)
        Else
          StrFmt = ""
        End If
        If InStr(Rng.Text, ",") > 0 Then
          Rng.Text = StrFmt & Format(Round(Rng.Text, 0), "#,###")
        Else
          Rng.Text = StrFmt & Round(Rng.Text, 0)
        End If
      End If
    Next
  End If
End With
End Sub

[ubns]

Thanks Paul.