Please tell me it doesn't take 7 statements to turn table borders off

[Jennifer Murphy]

I want to add code to a macro to turn off all but the bottom border in the header row of a table. I started the macro recorder, selected the first row, turned off all borders, then turned the bottom border back on. Here's the code I got:

Sub Macro1()
  Selection.Borders(wdBorderTop).LineStyle = wdLineStyleNone
  Selection.Borders(wdBorderLeft).LineStyle = wdLineStyleNone
  Selection.Borders(wdBorderBottom).LineStyle = wdLineStyleNone
  Selection.Borders(wdBorderRight).LineStyle = wdLineStyleNone
  Selection.Borders(wdBorderVertical).LineStyle = wdLineStyleNone
  Selection.Borders(wdBorderDiagonalDown).LineStyle = wdLineStyleNone
  Selection.Borders(wdBorderDiagonalUp).LineStyle = wdLineStyleNone
  With Selection.Borders(wdBorderBottom)
    .LineStyle = Options.DefaultBorderLineStyle
    .LineWidth = Options.DefaultBorderLineWidth
    .Color = Options.DefaultBorderColor
  End With
End Sub

Is there really no wdBorderAll variable or something equivalent?

[macropod]

Hi Jennifer,

You could use a loop:

Sub Demo()
Dim i As Long
With Selection.Tables(1)
  With .Rows(1).Range
    For i = 1 To .Borders.Count
      .Borders(i).LineStyle = wdLineStyleNone
    Next
    .Borders(wdBorderBottom).LineStyle = Options.DefaultBorderLineStyle
  End With
End With
End Sub

[Jennifer Murphy]

That's pretty clever. I never would have thought of that.

So I take it there is no wdBordersAll or something like that, right?

[macropod]

Originally Posted by Jennifer Murphy

So I take it there is no wdBordersAll or something like that, right?

You could use something like:
ActiveDocument.Tables(1).Rows(1).Borders.Enable = False
but that would remove the bottom border from the row as well. You might remedy that with code like:

With ActiveDocument.Tables(1)
  .Rows(1).Borders.Enable = False
  .Rows(2).Borders.Enable = True
End With

[sydneytroz]

Originally Posted by Jennifer Murphy

So I take it there is no wdBordersAll or something like that, right?

Since the border styles are stored in an array or some sort of indexed list, it looks like the other wd* variables are just indices, so a wdBordersAll wouldn't make sense.

If VBA was kept up with the .NET languages, you could do something like (I'm not familiar with VB .NET, so this is borrowing from the C# syntax)

Selection.Borders.ForEach(x => x.LineStyle = wdLineStyleNone)

...but that will probably never happen.

[macropod]

Yes, one could loop through the collection, but that still requires turning on/off seven separate border attributes.