create footnotes from custom text

[mosrozen]

Hello,


I am looking to write a vb script that I will create notes for examples:
I'm looking for (this is important) long.
(this is important) is the text extract for the new footnote on page
in place of a parenthesis between the extraction of numbering etc. Note 1
Eric
(just at present I work on Advent 3b2 with his own programming language, now I want to turn to VB, if you know a good "manual"?)

[macropod]

Hi Eric,

You could use a macro like:

Sub Demo()
Dim StrTxt As String
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "\(*\)"
    .Replacement.Text = ""
    .Forward = True
    .Wrap = wdFindStop
    .Format = True
    .MatchCase = False
    .MatchWholeWord = False
    .MatchWildcards = True
    .MatchSoundsLike = False
    .MatchAllWordForms = False
    .Execute
  End With
  Do While .Find.Found
    StrTxt = Mid(.Duplicate.Text, 2, Len(.Duplicate.Text) - 2)
    .Text = vbNullString
    .Footnotes.Add Range:=.Duplicate, Text:=StrTxt
    .Find.Execute
  Loop
End With
End Sub

As for vba coding resources, there are many web sites with tutorials, and you might one or two of them worth doing. Most are probably for Excel, though.

For a book, you might try something like 'The Secret Life of Word: A Professional Writer's Guide to Microsoft Word Automation' by R Delwood. This isn't a programming book, per se, and doesn't profess to teach you how to program. Rather, it shows how to combine Word's various tools (including vba) to achieve whatever the desried result might be. The only reason I can suggest this book is that I did much of the technical review; I'm sure there are plenty of others out there. Another that I contributed to is 'Word Hacks', by A Savikas, but that one pre-dates Office 2007.

[mosrozen]

hello,
thank you for your answer it's work fine.
i see for the manual
regards