Macro to loop in Word

[Yamaha Rider]

I have the word document that I want to color a particular wird a certain way. Attached is a sample with the Macro that I wrote. I now need to loop this macro throughout the document so does this throughtout hte document. Can somebody help me?

Here is what I have

Selection.Find.ClearFormatting
With Selection.Find
  .Text = "gopost`"
  .Replacement.Text = ""
  .Forward = True
  .Wrap = wdFindContinue
  .Format = False
  .MatchCase = False
  .MatchWholeWord = False
  .MatchWildcards = False
  .MatchSoundsLike = False
  .MatchAllWordForms = False
End With
Selection.Find.Execute
Selection.MoveLeft Unit:=wdCharacter, Count:=1
Selection.MoveRight Unit:=wdCharacter, Count:=2, Extend:=wdExtend
Selection.Font.color = wdColorRed
Selection.Font.Bold = wdToggle
Selection.MoveRight Unit:=wdCharacter, Count:=1
Selection.MoveRight Unit:=wdCharacter, Count:=4, Extend:=wdExtend
Selection.Font.color = 5296274
Selection.Font.Bold = wdToggle
Selection.MoveRight Unit:=wdCharacter, Count:=1
Selection.MoveRight Unit:=wdCharacter, Count:=1, Extend:=wdExtend
Selection.Font.color = wdColorRed
Selection.Font.Bold = wdToggle
Selection.MoveRight Unit:=wdCharacter, Count:=1
End Sub

[macropod]

Hi Yamaha Rider,

Try:

Sub Demo()
Application.ScreenUpdating = False
Dim Rng As Range
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Text = "gopost`"
    .Replacement.Text = ""
    .Forward = True
    .Wrap = wdFindStop
    .Format = True
    .MatchCase = False
    .MatchWholeWord = False
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
    .Execute
  End With
  Do While .Find.Found
    .Font.Bold = True
    .Font.Color = wdColorRed
    Set Rng = .Duplicate
    Rng.Start = Rng.Start + 2
    Rng.End = Rng.End - 1
    Rng.Font.Color = 5296274
    .Collapse wdCollapseEnd
    .Find.Execute
  Loop
End With
Application.ScreenUpdating = True
End Sub

[Yamaha Rider]

Awesome, Thank you