Add filename to imported text

[knpaddac]

I frequently need to import the content from hundreds of files into a single document. I would like to have the filename included as text above each file's content in the final document. Is there a way to do this by adding it into the code I use (listed below):

Sub Import_Text()
Application.ScreenUpdating = False
Dim strFolder As String, strFile As String, wdDoc As Document, rtfFile As Document
strFolder = GetFolder
If strFolder = "" Then Exit Sub
strFile = Dir(strFolder & "\*.rtf", vbNormal)
Set wdDoc = ActiveDocument
While strFile <> ""
  Set rtfFile = Documents.Open(FileName:=strFolder & "\" & strFile, AddToRecentFiles:=False, Visible:=False, ConfirmConversions:=False)
  wdDoc.Range.InsertAfter rtfFile.Range.Text & vbCr
  rtfFile.Close SaveChanges:=True
  strFile = Dir()
Wend
Set rtfFile = Nothing: Set wdDoc = Nothing
Application.ScreenUpdating = True
End Sub
 
Function GetFolder() As String
Dim oFolder As Object
GetFolder = ""
Set oFolder = CreateObject("Shell.Application").BrowseForFolder(0, "Choose a folder", 0)
If (Not oFolder Is Nothing) Then GetFolder = oFolder.Items.Item.Path
Set oFolder = Nothing
End Function

[rollis13]

In the macro change the line of code to this:

wdDoc.Range.InsertAfter rtfFile & vbCr & rtfFile.Range.Text & vbCr

[vivka]

Hi, try replacing
wdDoc.range.InsertAfter rtfFile.range.text & vbCr
with:
wdDoc.range.InsertAfter strFile & vbCr & rtfFile.range.text & vbCr

[knpaddac]

This did exactly what I needed. thanks

Originally Posted by rollis13

In the macro change the line of code to this:

wdDoc.Range.InsertAfter rtfFile & vbCr & rtfFile.Range.Text & vbCr

[knpaddac]

had to change the single instance of 'strFile' to 'rtfFile' but that did the trick.

Originally Posted by vivka

Hi, try replacing
wdDoc.range.InsertAfter rtfFile.range.text & vbCr
with:
wdDoc.range.InsertAfter strFile & vbCr & rtfFile.range.text & vbCr

[rollis13]

Thanks for the positive feedback , glad we were able to help.