Split table cell into multiple rows based on a delimiter

[WJSwanepoel]

I have a table where I want to select a cell and split it into multiple rows based on a delimiter (e.g. a paragraph mark).

What is the best way to achieve this with the minimum effort?

I use Word 2007.

I found one way of getting it done, but it loses certain formatting which has to be redone, e.g. Paragraph indenting.


If I copy the table to Excel it will automatically put the lines ending in a paragraph mark in separate rows. I then copy the Excel table back to Word and then reformat it. I would however prefer an automated way since my documents contain many (hundreds) such tables.

[macropod]

For example:

Sub Demo()
Application.ScreenUpdating = False
Dim Tbl As Table, r As Long, c As Long, Rng As Range
For Each Tbl In ActiveDocument.Tables
  With Tbl
    For r = .Rows.Count To 1 Step -1
      Do While .Cell(r, 1).Range.Paragraphs.Count > 1
        If r < .Rows.Count Then
          .Rows.Add BeforeRow:=.Rows(r + 1)
        Else
          .Rows.Add
        End If
          For c = 1 To .Columns.Count
            Set Rng = .Cell(r, c).Range.Paragraphs.Last.Range
            Rng.End = Rng.End - 1
            With .Cell(r + 1, c).Range.Paragraphs.Last.Range
              .ParagraphFormat = Rng.ParagraphFormat
              .FormattedText = Rng.FormattedText
            End With
            Rng.Start = Rng.Start - 1
            Rng.Delete
          Next
      Loop
    Next
  End With
Next
Application.ScreenUpdating = True
End Sub

[WJSwanepoel]

Good day Paul,
Thank you very, very much for the assistance.

I tested your code on one of my files, and it works 100% correctly! I will flag the thread as resolved.

Regards,
Willem Swanepoel

[WJSwanepoel]

If I wanted to change any other properties, eg. Font, how would I be able to do that?

[macropod]

That all depends on what/when you want to make those changes. I suggest you start a new thread for that.