Option Explicit

Sub UpdateTable()
Dim oSource As Document
Dim oTarget As Document
Dim oRng As Range
Dim strFind As String
    'Open the document with the table
    Set oTarget = Documents.Open("C:\Path\EN\Target.docx")
    'Open the document with the list
    Set oSource = Documents.Open("C:\Path\EN\Source.docx")
    Set oRng = oSource.Range
    With oRng.Find
        With oRng.Find
            Do While .Execute(FindText:="US[0-9]{5,}", _
                              MatchWildcards:=True)        'The number as shown in the list document
                strFind = Trim(Replace(oRng.Text, "US", ""))        'Remove the 'US' Prefix from the found number
                oRng.MoveEnd wdParagraph, 5        'Move the end of the range that encompasses the found text the end of the required text
                oRng.MoveStart wdParagraph, 1        'Move the start of the range to start of the paragraph after the paragraph with the found text
                FillTable oTarget, oRng, strFind        'Call the sub to fill the table with the text from the range
                oRng.Collapse 0
            Loop
        End With
    End With
lbl_Exit:
    Set oSource = Nothing
    Set oTarget = Nothing
    Set oRng = Nothing
    Exit Sub
End Sub

Private Sub FillTable(oDoc As Document, _
                      oRng As Range, _
                      strFind As String)
Dim oCell As Range
Dim oFind As Range
Dim iRow As Long
    Set oFind = oDoc.Range
    With oFind.Find
        Do While .Execute(FindText:=strFind)
            iRow = oFind.Information(wdEndOfRangeRowNumber)
            Set oCell = oDoc.Tables(1).Rows(iRow).Cells(5).Range
            oCell.End = oCell.End - 1
            oCell.FormattedText = oRng.FormattedText        'use this line to keep the formatting
            'oCell.Text = oRng.Text 'use this line if the formatting is not required
            Exit Do
        Loop
    End With
lbl_Exit:
    Set oCell = Nothing
    Set oFind = Nothing
    Exit Sub
End Sub

Set oCell = oDoc.Tables(1).Rows(iRow).Cells(5).Range
    oCell.End = oCell.End - 1
    If Len(oCell) = 0 Then 'Add This line
        oCell.FormattedText = oRng.FormattedText        'use this line to keep the formatting
        'oCell.Text = oRng.Text 'use this line if the formatting is not required
        Exit Do
    End If 'And this one