Importing styles using Templates only if style is not present already

[Bikram]

Greetings to all, I am trying to copy styles from a template only if that style is not present in Activedocument. I am using following code:

Function styleimporter(st1 As String, st2 As String)
Dim i As Integer
On Err.Number = 5834 GoTo exx
Dim a()
a = Array(st1, st2)
For i = LBound(a) To UBound(a)
On Error GoTo exx
    With ActiveDocument.Range.find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Style = a(i)
        .Execute
exx:
    If .Execute = False Then
        Application.OrganizerCopy _
        Source:="C:\Users\aspKamal\AppData\Roaming\Microsoft\Templates\NecessaryStyles.dotm.docx", _
        Destination:=ActiveDocument.FullName, _
        name:=a(i), _
        Object:=wdOrganizerObjectStyles
    End If
    End With
Next
End Function

Here, It seems that in order to search for a style in a document, the style should be present on Activedocument otherwise it encounters error 5834 "Item with the specified name does not exist". I tried to handle it with "on error goto exx" but it only works for the first item and for the second item again throws the same error. Any thought on how I could resolve this issue would be of great help.
Thanks,
Bikram

[macropod]

Perhaps:

Sub AddStyles()
Application.ScreenUpdating = False
Dim DocSrc As Document, DocTgt As Document, Stl As Style, StrStls As String, i As Long
StrStls = "|"
With Application.FileDialog(FileDialogType:=msoFileDialogFilePicker)
  .Title = "Select the source document containing the required Styles"
  .AllowMultiSelect = False
  If .Show = -1 Then
    Set DocSrc = Documents.Open(.SelectedItems(1), ReadOnly:=True, AddToRecentFiles:=False)
  Else
    MsgBox "No source file selected. Exiting", vbExclamation
    Exit Sub
  End If
End With
With Application.FileDialog(FileDialogType:=msoFileDialogFilePicker)
  .Title = "Select the document to be updated"
  .AllowMultiSelect = False
  If .Show = -1 Then
    Set DocTgt = Documents.Open(.SelectedItems(1), ReadOnly:=False, AddToRecentFiles:=True)
  Else
    MsgBox "No target file selected. Exiting", vbExclamation
    DocSrc.Close SaveChanges:=False
    Set DocSrc = Nothing
    Exit Sub
  End If
End With
For Each Stl In DocSrc.Styles
  If Stl.BuiltIn = False Then StrStls = StrStls & Stl.NameLocal & "|"
Next
For Each Stl In DocTgt.Styles
  If Stl.BuiltIn = False Then StrStls = Replace(StrStls, "|" & Stl.NameLocal & "|", "|")
Next
For i = 1 To UBound(Split(StrStls, "|")) - 1
  Application.OrganizerCopy Source:=DocSrc.Fullname, Destination:=DocTgt.Fullname, Name:=Split(StrStls, "|")(i), Object:=wdOrganizerObjectStyles
Next
DocTgt.Close SaveChanges:=True: DocSrc.Close SaveChanges:=False
Set DocSrc = Nothing: Set DocTgt = Nothing
Application.ScreenUpdating = True
MsgBox "Successfully added missing Styles"
End Sub

[Bikram]

Thank you very much, Macropod.

[JingleBelle]

Thank you!

I tried the code, and it worked like a charm. This will be very helpful, indeed. Thank you, again.