Save all docs to pdf in specified folder

[loki005]

Hello there,



I need to be able to save all documents in a specified folder, while retaining those documents original file names.

Note: I read previously where someone was having issues with emailing the saved pdfs thereafter, but wasn't able to figure out what was done to correct that issue. As I haven't gotten to that point yet, I am not certain about the issue with emailing the pdfs after the fact, but I can say that I will need to be able to email the pdf documents after they have been saved/converted from another doc type

Code:

Sub AcceptSave()
'
' AcceptSave Macro
'
'
ActiveDocument.AcceptAllRevisions
ActiveDocument.TrackRevisions = False
Application.Run MacroName:="Silent_save_to_PDF"
ActiveDocument.Save
End Sub
 
Sub Silent_save_to_PDF()
'
' Silent_save_to_PDF Macro
'
ActiveDocument.ExportAsFixedFormat OutputFileName:= _
Replace(ActiveDocument.FullName, ".docx", ".pdf"), _
ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False, OptimizeFor:= _
wdExportOptimizeForPrint, Range:=wdExportAllDocument, Item:= _
wdExportDocumentContent, IncludeDocProps:=False, KeepIRM:=True, _
CreateBookmarks:=wdExportCreateNoBookmarks, DocStructureTags:=True, _
BitmapMissingFonts:=True, UseISO19005_1:=False
End Sub

Thank you.

[macropod]

Try:

Sub ConvertDocs2PDFs()
Application.ScreenUpdating = False
Dim strFolder As String, strFile As String, strDocNm As String, wdDoc As Document
strDocNm = ActiveDocument.FullName
strFolder = GetFolder
If strFolder = "" Then Exit Sub
strFile = Dir(strFolder & "\*.doc", vbNormal)
While strFile <> ""
  If strFolder & "\" & strFile <> strDocNm Then
    Set wdDoc = Documents.Open(FileName:=strFolder & "\" & strFile, AddToRecentFiles:=False, Visible:=False)
    With wdDoc
      .SaveAs FileName:=Split(.FullName, ".doc")(0) & ".pdf", FileFormat:=wdFormatPDF, AddToRecentFiles:=False
      .Close SaveChanges:=False
    End With
  End If
  strFile = Dir()
Wend
Set wdDoc = Nothing
Application.ScreenUpdating = True
End Sub

Function GetFolder() As String
Dim oFolder As Object
GetFolder = ""
Set oFolder = CreateObject("Shell.Application").BrowseForFolder(0, "Choose a folder", 0)
If (Not oFolder Is Nothing) Then GetFolder = oFolder.Items.Item.Path
Set oFolder = Nothing
End Function

For PC macro installation & usage instructions, see: http://www.gmayor.com/installing_macro.htm

[loki005]

Thank you very much,

As I am extremely new to Macros (I plan on taking courses over the coming weeks), will I simply use your code to create a new macros and then add that to my existing macros that accepts all changes to the word document I am working on?

[macropod]

I already posted a link telling you how to install & use the macro...

As for accepting changes, although your own macro has code for that, it's not apparent how that's relevant to a folder full of documents. Are you suggesting those documents, too, might have tracked changes that you want accepted? If so, after:
With wdDoc
insert:

      .TrackRevisions = False
      .AcceptAllRevisions

[loki005]

Thank you so much Paul,

I wasn't suggesting anything, just so much of a novice I didn't realize you provided me a link so that I can use.

Thanks again and my apologies if I came off as daft.