VBA Code to Insert Legacy Text Field

[PSSMargaret]

Thanks Graham. Almost there. If I have ten sets of fields in the form and run the macro, it successfully inserts a new set of field just below the current cursor position, however, it returns the cursor to the top set of fields so I have to tab through them all to get to the new set of fields just entered.

[gmayor]

Name the fields added separately and select the first of them e.g.

Option Explicit

Sub CreateTextField()
Dim oRng As Range
Dim aFld As FormField, bFld As FormField
    If ActiveDocument.ProtectionType <> wdNoProtection Then ActiveDocument.Unprotect
    Selection.Paragraphs(1).Range.InsertParagraphAfter
    Set oRng = Selection.Paragraphs(1).Range.Next.Paragraphs(1).Range
    With oRng
        .ParagraphFormat.SpaceBefore = 3
        .Collapse 1
        Set aFld = .FormFields.Add(Range:=oRng, Type:=wdFieldFormTextInput)
        aFld.TextInput.EditType Type:=wdRegularText, Default:="Category", Format:="First capital"
        .End = aFld.Range.End
        .Font.Bold = True
        .Collapse 0
        .Text = ":  "
        .Font.Bold = False
        .Collapse 0
        Set bFld = .FormFields.Add(Range:=oRng, Type:=wdFieldFormTextInput)
        bFld.TextInput.EditType Type:=wdRegularText, Default:="Detail", Format:="First capital"
        .End = bFld.Range.End
        .Collapse 0
        aFld.Select 'select the first of the two added fields
    End With
lbl_Exit:
    ActiveDocument.Protect Type:=wdAllowOnlyFormFields, NoReset:=True
    Set oRng = Nothing
    Set aFld = Nothing
    Set bFld = Nothing
    Exit Sub
End Sub

[PSSMargaret]

Perfect! Thanks so much.