Picture Bullets not flowing from Master Slide to custom layout content placeholders

lynnydd · #1 06-17-2016, 02:02 AM

Hi guys,

I have a Master Template with 50 different custom layouts. They have a combination of placeholders throughout.

I am using picture bullets where bullets exist but I'm finding that the formatting from the Master Layout (which only allows a text placeholder) is not flowing down to the content placeholders on the custom layouts.

Any ideas on how I can get them to flow or to speed the process of adding picture bullets up?

JohnWilson · #2 06-17-2016, 09:19 AM

Usually if the master bullets don't apply to the layouts it means that someone at some time has manually modified the layouts. Sadly there is no simple way to reverse this unless you are ably to modify the XML code to unset the manual bullets or remake all of the layouts. Both are going to be quite a job!

You might be able to automate remaking the layouts with code. Make sure you try this on a copy as it isn't foolproof!

Copy the code below and in PPT Alt f11 to get to the code editor. INSERT > Module and paste in the code f5 to run it. If you are lucky it might fix thinks in seconds.

Code:

Sub fixPLC()
   Dim ocl As CustomLayout
   Dim oshp As Shape
   Dim sngL As Single
   Dim sngT As Single
   Dim sngW As Single
   Dim sngH As Single
   Dim P As Long
   Dim raySize(7) As Long
   For Each ocl In ActivePresentation.SlideMaster.CustomLayouts
      For Each oshp In ocl.Shapes
         If oshp.Type = msoPlaceholder Then
            If oshp.PlaceholderFormat.Type = 7 Then
               sngW = oshp.Width
               sngH = oshp.Height
               sngT = oshp.Top
               sngL = oshp.Left
               For P = 1 To oshp.TextFrame2.TextRange.Paragraphs.Count
                  raySize(P) = oshp.TextFrame2.TextRange.Paragraphs(P).Font.Size
               Next P
               oshp.Delete
               With ocl.Shapes.AddPlaceholder(7)
                  .Width = sngW
                  .Left = sngL
                  .Top = sngT
                  .Height = sngH
                  For P = 1 To .TextFrame2.TextRange.Paragraphs.Count
                     .TextFrame2.TextRange.Paragraphs(P).Font.Size = raySize(P)
                  Next P
               End With
            End If
         End If
      Next oshp
   Next ocl
End Sub

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Slide Master indent settings for bullets not correct when applied to regular slide	jleet24	PowerPoint	1	04-07-2015 12:16 PM
Master slide placeholder text - make completely custom for each layout	lhulmef	PowerPoint	1	03-25-2015 03:03 PM
Powerpoint 13 - placeholders in Slide Master end up in the wrong place when viewing presentation	chisao101	PowerPoint	0	02-14-2015 02:09 PM
What is purpose of slide master, as opposed to slide layout	meileetan	PowerPoint	3	01-10-2014 02:20 AM
Master Layout - Placeholders place themselves on top	regsnerven	PowerPoint	1	07-22-2011 12:26 AM