Extract links from PowerPoint to FlowChart

[RoyLittle0]

Hi All

I have a PowerPoint presentation that acts as a Flow Chart, It is a fault diagnostic tool that lets the user choose options which links to the next action to be taken, There are 116 pages and all work from links from another page.



The original powerPoint was created from a flow chart, when I say created I meant it was painstakingly written based on a flow chart, but the flow chart hasn't been updated where the PowerPoint has, so I need to now update the flowchart to match the PowerPoint, although I don't know exactly what has been updated, so I need a way of tracing the links from page to page, without having to click on each page and manually find them.

Is there a way that I can get the link data from the PowerPoint, so basically
Slide 1 Links to Slide 10 and 22
Slide 10 links to Slide 18 and 100, etc, etc
Preferably in a Visual way

[JohnWilson]

The only way would be to use vba code.

IF the links are all of type link to slide xx (NOT NEXT, PREVIOUS etc)

You could try this to add the links as text just off slide.

Sub chexLinks()
Dim osld As Slide
Dim ohl As Hyperlink
Dim txtBox As Shape
Dim strLinks As String
Dim lngID As Long
Dim lngPos As Long
Dim b_found As Boolean
Call removeall
For Each osld In ActivePresentation.Slides
For Each ohl In osld.Hyperlinks
If ohl.Address = "" Then 'internal
lngPos = InStr(ohl.SubAddress, ",")
lngID = CLng(Left(ohl.SubAddress, lngPos - 1))
If lngPos > 0 Then
b_found = True
strLinks = strLinks & "Link to Slide " & ActivePresentation.Slides.FindBySlideID(lngID).SlideIndex & vbCrLf
End If
End If
Next ohl
If b_found Then
Set txtBox = osld.Shapes.AddLabel(msoTextOrientationHorizontal, -120, 10, 120, 100)
txtBox.TextFrame.TextRange = strLinks
txtBox.TextFrame.TextRange.Font.Size = 12
txtBox.Name = "Link report"
End If
b_found = False
strLinks = ""
Next osld
End Sub

Sub removeall()
Dim osld As Slide
For Each osld In ActivePresentation.Slides
On Error Resume Next
osld.Shapes("Link report").Delete
Next osld
End Sub

Don't know what to do with the code?

[RoyLittle0]

Thanks for the reply, i get an syntax error on the below line

strLinks = strLinks & "Link to Slide " & ActivePresentation.Slides.FindBySlideID(lngID).Sli deIndex & vbCrLf

[JohnWilson]

The website seems to have inserted a space that wasn't in what I posted.
strLinks = strLinks & "Link to Slide " & ActivePresentation.Slides.FindBySlideID(lngID).Sli deIndex & vbCrLf
Try changing Sli deIndex to SlideIndex

[RoyLittle0]

That's better,

Works perfect, thank you

[JohnWilson]

Should make the job a little easier!