recording macro in ppt 2007

[rwab]

I have 2007, in 2003 I could record a macro, but in 2007 ppt I cannot seem to find the control to record a macro?

The below macro worked in 2003, but does not work in 2007, its a simple fit to page function:

ActiveWindow.Selection.ShapeRange.ScaleWidth 1, msoFalse, msoScaleFromBottomRight
ActiveWindow.Selection.ShapeRange.ScaleHeight 1, msoFalse, msoScaleFromBottomRight
ActiveWindow.Selection.ShapeRange.ScaleWidth 1, msoFalse, msoScaleFromTopLeft
ActiveWindow.Selection.ShapeRange.ScaleHeight 1, msoFalse, msoScaleFromTopLeft
End Sub

[PetLahev]

In PPT 2007 you can't record macro :-(

What about this code

Dim shp As ShapeRange
    If ActiveWindow.Selection.Type = ppSelectionShapes Then
        Set shp = ActiveWindow.Selection.ShapeRange
        shp.Left = 0
        shp.Top = 0
        shp.Height = ActivePresentation.PageSetup.SlideHeight
        shp.Width = ActivePresentation.PageSetup.SlideWidth
    End If
    Set shp = Nothing

[rwab]

I get a comile error and it highlights the word activewindow in the macro

[rwab]

I have office 2007 Powerpoint now and I cannot figure out a macro to fit a screen shot to an outline on the PPT I have created, it must fit within this outline, each ppt file is 7 pages and I have 300 files to create, I used to record a macro, but Microsoft decided to omit the record macro from office 2007, way to go Billy!, we are going backwards now???? Anyway ok I feel better, ok no I dont, is there anyone that can write my macro I recorded in 2003 for 2007???

Is this the best sight to ask questions like this, if anyone knows the best place let me know, have no idea?

[rwab]

Does anyone know of a real Powerpoint site where there is actually someone assisting users for the Pathetic PPT 2007 version????

[Alchemy]

Does this work??

Dim oshp As Shape
Dim osld As Slide
Set osld = ActiveWindow.View.Slide
Set oshp = osld.Shapes(osld.Shapes.Count)
oshp.Left = 0
oshp.Top = 0
oshp.Height = ActivePresentation.PageSetup.SlideHeight
oshp.Width = ActivePresentation.PageSetup.SlideWidth
Set oshp = Nothing
Set osld = Nothing

[rwab]

This fits to the entire ppt page, I have an outline on the ppt page that I need it to fit, I have attached the ppt file with the page outline.

Can you make the code have it fit within the outline?

Also in 2003 my code fit to all pages in the file as all slides were the same, the code you provided requires residing on each page... can you make it fit all pages in the ppt file when open?

[JohnWilson]

See if this gets you closer:

Sub FittopageCurrent()
'Fits the last added shape to the box on the master
'on current slide
Dim oshp As Shape
Dim osld As Slide
Dim otarget As Shape
Set otarget = ActivePresentation.SlideMaster.Shapes("Rectangle 8")
Set osld = ActiveWindow.View.Slide
Set oshp = osld.Shapes(osld.Shapes.Count)
oshp.Left = otarget.Left
oshp.Top = otarget.Top
oshp.LockAspectRatio = False
oshp.Height = otarget.Height
oshp.Width = otarget.Width
Set oshp = Nothing
Set osld = Nothing
End Sub

Sub FittopageAll()
'Fits the last added shape to the box on the master
'on all slides
Dim oshp As Shape
Dim osld As Slide
Dim otarget As Shape
Set otarget = ActivePresentation.SlideMaster.Shapes("Rectangle 8")
For Each osld In ActivePresentation.Slides
If osld.Shapes.Count > 0 Then
Set oshp = osld.Shapes(osld.Shapes.Count)
oshp.Left = otarget.Left
oshp.Top = otarget.Top
oshp.LockAspectRatio = False
oshp.Height = otarget.Height
oshp.Width = otarget.Width
End If
Next osld
Set oshp = Nothing
Set osld = Nothing
End Sub

[rwab]

Perfection, thanks much.....