Attaching all PDFs in folder to Outlook email

[handclips]

Hi

I want to attach all PDFs in a specific desktop folder to an Outlook email using VBA in Word

I'm using below code to generate an Outlook email but cant figure out how to write the attachment part.

Sub Email_Template1()

Dim oMailItem As Object, oOLapp As Object
Dim Word As Object, doc As Object, MsgTxt$
Set oOLapp = CreateObject("Outlook.Application")
Set oMailItem = oOLapp.CreateItem(0)


Set Word = CreateObject("word.application")

With oMailItem
.To = "Email"
.cc = "Email"
.subject = "Needed Confirmation"
' .attachment.Add
.HTMLBody = "test"
.Display
End With

Set oOLapp = Nothing
Set oMailItem = Nothing

End Sub

[gmayor]

Cross posted at Reload this Page Attaching all PDFs in folder to Outlook email using Word VBA
and Attaching all PDFs in folder to Outlook email using Word VBA - Excel VBA / Macros - OzGrid Free Excel/VBA Help Forum

That's fairly straightforward e.g.

Dim oMailItem As Object, oOLApp As Object
Dim Word As Object, doc As Object, MsgTxt$
Dim strFile As String
Const strPath As String = "C:\Path\"
    Set oOLApp = CreateObject("Outlook.Application")
    Set oMailItem = oOLApp.CreateItem(0)
    'Set Word = CreateObject("word.application") '?

    With oMailItem
        .To = "Email"
        .CC = "Email"
        .Subject = "Needed Confirmation"
        strFile = Dir$(strPath & "*.pdf")
        While strFile <> ""
            .Attachments.Add strPath & strFile
            strFile = Dir$()
        Wend
        .HTMLBody = "test"
        .Display
    End With

    Set oOLApp = Nothing
    Set oMailItem = Nothing

[macropod]

Handclips: This is the second time you've been caught cross-posting without providing links. Third strike and you're out.