Can Outlook create other appointments from one entry?

[FearlessStamper]

At my law firm, when we get a trial date, we have quite a few other appointments that are created based on that date. For instance, Plaintiff Expert Witness Deadline is 120 days before the trial, motions for summary judgment deadline is 90 days before trial, etc.



Is there any way to set an appointment for the trial date and then have other appointments generated based on that appointment entry date?

I just hate having to create 15 other appointments if I can help it.

Many thanks!

[gmayor]

The short answer is yes, but in order to assist we would need more information. Do we take it that one trial date creates 16 appointments?

Are there always the same number of appointments with the same delay period?

What is the information to be recorded in the appointments?

Do the appointments create attendees and thus e-mail messages?

[FearlessStamper]

The short answer is yes, but in order to assist we would need more information. Do we take it that one trial date creates 16 appointments?

YES. for one trial date, there will be 16 other appointments.

Are there always the same number of appointments with the same delay period?

Some of the appointments may have a 31 day delay, 90 day delay, 180 day delay, etc. but for all cases, the delays will be the same amount of days from the date of trial for each appointment type.

What is the information recorded in the appointments?

The information recorded will have the standard brief case info for each appointment -- "123-456 Smith v. Jones" and also the specific appointment type "Plaintiff Expert Witness Deadline," "Motions in Limine Deadline," etc.

Andrea

[gmayor]

OK - based on the information you have provided, you need a macro something like the following. This prompts for the case details and a trial date and then creates the appointments. I have included the two deadlines for which you have supplied data. You will need to add the additional deadlines by copying the line to where it says 'etc

CreateAppointment strCase & " - Plaintiff Expert Witness Deadline", CStr(dStart - 120)

and changing the data in red to the type of deadline and the number of days before the trial as appropriate.

It could be made more sophisticated, but this will do the job.

Option Explicit

Sub CreateTrialAppointments()
Dim strDate As String
Dim dStart As Date
Dim iDelay As Integer
Dim strCase As String
    strCase = InputBox("Enter Case")
    strDate = InputBox("Enter Trial Date - 'mm/dd/yyyy'")
    If IsDate(strDate) Then
        dStart = CDate(strDate)
        CreateAppointment strCase & " - Trial Date", strDate
        
        CreateAppointment strCase & " - Plaintiff Expert Witness Deadline", CStr(dStart - 120)
        CreateAppointment strCase & " - Motions for Summary Judgment Deadline", CStr(dStart - 90)
        'etc
    End If
lbl_Exit:
    Exit Sub
End Sub

Private Sub CreateAppointment(strSubject As String, _
                      strDate As String)
Dim olItem As AppointmentItem
    Set olItem = CreateItem(olAppointmentItem)
    With olItem
        .MeetingStatus = olNonMeeting
        .Subject = strSubject
        .Start = strDate
        .AllDayEvent = True
        .Save
    End With
    Set olItem = Nothing
lbl_Exit:
    Exit Sub
End Sub