How to reset outlook style

PRA007 · #1 03-22-2016, 09:55 AM

I have in my clipboard that I want to paste to outlook editor and after that I want to format all the text to be normal style. How to do that.

Here is the code that I got from (I forget but it was from Greg Maxy)

Code:

Sub sendcomplexemail()

Dim olapp As Object
Dim olemail As Object
Dim olInsp As Object
Dim wddoc As Object

    On Error Resume Next
    Set olapp = GetObject(, "Outlook.Application")
    If Err <> 0 Then Set olapp = CreateObject("Outlook.Application")
    On Error GoTo 0
    Set olemail = olapp.CreateItem(0)
    With olemail
        .BodyFormat = 3
        .To = ""
        .Subject = "Movies Report"
        Set olInsp = .GetInspector
        Set wddoc = olInsp.WordEditor
        Set orng = wddoc.Range
        orng.Paste
        orng.Style = "normal"
        .Display
    End With
End Sub

I am not able to work with red part.

gmayor · #2 03-22-2016, 10:06 PM

The style names are case sensitive, so the correct code would be as follows. Note that this code sequence is normally intended to be run from applications other than Outlook (though it will run from Outlook VBA). Set the range to the start of the document range if you wish to include the signature in your message (as shown). You must always include .Display, even if the next line is .Send.

Use html body format (2).

Code:

Option Explicit

Sub sendcomplexemail()

Dim olApp As Object
Dim olEmail As Object
Dim olInsp As Object
Dim wdDoc As Object
Dim oRng As Object

    On Error Resume Next
    Set olApp = GetObject(, "Outlook.Application")
    If Err <> 0 Then Set olApp = CreateObject("Outlook.Application")
    On Error GoTo 0
    Set olEmail = olApp.CreateItem(0)
    With olEmail
        .BodyFormat = 2
        .To = ""
        .Subject = "Movies Report"
        Set olInsp = .GetInspector
        Set wdDoc = olInsp.WordEditor
        Set oRng = wdDoc.Range(0, 0)
        oRng.Paste
        oRng.Style = "Normal"
        .Display
    End With
lbl_Exit:
    Set olApp = Nothing
    Set olEmail = Nothing
    Set olInsp = Nothing
    Set wdDoc = Nothing
    Set oRng = Nothing
    Exit Sub
End Sub

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
How to 'Reset' Outlook Contacts?	markg2	Outlook	1	04-11-2015 08:26 AM
Use multiple style sets in the same Word document (depending on which section the style is in)	Ricyteach	Word VBA	6	03-09-2015 07:11 PM
outlook will not let me reset my password	bbauer	Outlook	0	08-20-2014 11:41 AM
reset numbering to 1 by paragraph Style	Helix86	Word	5	08-07-2013 10:48 PM
MS Outlook Addin not responding after menu bar reset	sunil_pagare	Outlook	0	10-14-2009 10:34 PM