Microsoft Office Forums

Go Back   Microsoft Office Forums > >

Reply
 
Thread Tools Display Modes
  #1  
Old 01-22-2015, 12:48 PM
meppwc meppwc is offline Outlook 2010 Read Receipts Windows 7 32bit Outlook 2010 Read Receipts Office 2007
Novice
Outlook 2010 Read Receipts
 
Join Date: Oct 2012
Posts: 6
meppwc is on a distinguished road
Default Outlook 2010 Read Receipts


I have found that if in Word or Excel I do a Save and Send of a document or spreadsheet; Outlook sends the attachment to the recipient successfully, but I never get an Outlook read receipt. For that matter, my Outlook signature does not appear in the email body either.

If I send an email directly from Outlook I always get a read receipt and my signature always appears.

Is there an Outlook setting that I am missing? Or ???
Reply With Quote
  #2  
Old 01-22-2015, 05:04 PM
niton niton is offline Outlook 2010 Read Receipts Windows 7 64bit Outlook 2010 Read Receipts Office 2010 64bit
Competent Performer
 
Join Date: Jul 2012
Posts: 102
niton is on a distinguished road
Default

The full Outlook is not used in a Save and Send from Word or Excel.

See here for more http://www.howto-outlook.com/howto/senddocasmail.htm
Reply With Quote
  #3  
Old 01-23-2015, 12:09 AM
gmayor's Avatar
gmayor gmayor is offline Outlook 2010 Read Receipts Windows 7 64bit Outlook 2010 Read Receipts Office 2010 32bit
Expert
 
Join Date: Aug 2014
Posts: 4,101
gmayor has much to be proud ofgmayor has much to be proud ofgmayor has much to be proud ofgmayor has much to be proud ofgmayor has much to be proud ofgmayor has much to be proud ofgmayor has much to be proud ofgmayor has much to be proud of
Default

You can use the following macro in either Word or Excel. 'MacroWord' and 'MacroExcel' show how to call it from those applications with the data you wish to supply.

You can of course use named files instead of the activefiles.

Re-instate the '.Send' command when you are happy it works for you.

Code:
Sub MacroWord()
    Dim strMessageBody As String
    strMessageBody = "This is the body of the message." & vbCr & "etc"
    ActiveDocument.Save 'it is important to save the item you are sending - here the active document
    
    Send_As_Mail "someone@somewhere.com", _
                 "Attachment: " & ActiveDocument.name, _
                 strMessageBody, _
                 ActiveDocument.FullName
End Sub

Sub MacroExcel()
    Dim strMessageBody As String
    strMessageBody = "This is the body of the message." & vbCr & "etc"
    ActiveWorkbook.Save 'it is important to save the item you are sending - here the active workbook
    
    Send_As_Mail "someone@somewhere.com", _
                 "Attachment: " & ActiveWorkbook.Name, _
                 strMessageBody, _
                 ActiveWorkbook.FullName
End Sub

Public Sub Send_As_Mail(strTo As String, _
                 strSubject As String, _
                 strMessage As String, _
                 Optional strAttachment As String)

' send the document as an attachment _
  in an Outlook Email message
Dim olApp As Object
Dim olInsp As Object
Dim oItem As Object
Dim oDoc As Object
Dim orng As Object

    On Error Resume Next
    
    'Get Outlook if it's running
    Set olApp = GetObject(, "Outlook.Application")

    'Outlook wasn't running, start it from code
    If Err <> 0 Then
        Set olApp = CreateObject("Outlook.Application")
    End If
    On Error GoTo 0

    'Create a new mailitem
    Set oItem = olApp.CreateItem(0)

    With oItem
        .to = strTo
        .Subject = strSubject
        If Not strAttachment = "" Then .Attachments.Add strAttachment
        .BodyFormat = 2        'olFormatHTML
        Set olInsp = .GetInspector
        Set oDoc = olInsp.WordEditor
        Set orng = oDoc.Range(0, 0)
        orng.Text = strMessage & vbCr
        .Display
        '.Send 'restore fter testing
    End With
lbl_Exit:
    Set oItem = Nothing
    Set olApp = Nothing
    Set olInsp = Nothing
    Set oDoc = Nothing
    Set orng = Nothing
    Exit Sub
End Sub
__________________
Graham Mayor - MS MVP (Word) (2002-2019)
Visit my web site for more programming tips and ready made processes www.gmayor.com
Reply With Quote
Reply

Thread Tools
Display Modes


Similar Threads
Thread Thread Starter Forum Replies Last Post
Outlook sending Not Read receipt when read receipts are disabled abrown1983 Outlook 1 07-16-2021 04:33 AM
2007 where is the config tab for read receipts? frustratedagain Outlook 0 12-17-2012 02:51 PM
Acknowledging Read Receipts dkenefake Outlook 2 05-03-2011 05:37 PM
Outlook 2010 Read Receipts Outlook 2007 - Receiving Multiple "read receipts" from a single email garp2100 Outlook 1 12-03-2010 07:10 AM
Read Receipts Programs vlandau Outlook 0 12-27-2006 09:58 AM

Other Forums: Access Forums

All times are GMT -7. The time now is 04:13 AM.


Powered by vBulletin® Version 3.8.11
Copyright ©2000 - 2024, vBulletin Solutions Inc.
Search Engine Optimisation provided by DragonByte SEO (Lite) - vBulletin Mods & Addons Copyright © 2024 DragonByte Technologies Ltd.
MSOfficeForums.com is not affiliated with Microsoft