Microsoft Outlook Movemail

[Microchip]

I am trying to write an Outlook program to move mail to a specific folder based on text in the subject, or anything else.

The program can move mail from the Inbox to a subfolder of Inbox, but I can't for the life of me figure out how to make it go to a folder called "Confirmed", which is NOT a subfolder of Inbox.

Any help would be greatly appreciated!

Here is the source code:
Option Explicit
Sub Analyze()
' This program will analyze the Outlook Inbox
On Error GoTo Analyze_Err
' The NameSpace is the object that gives you access to all of Outlook's Folders.
' In Outlook, there is only one, and it is called "MAPI", which
' is an acronym for Messaging Application Programming Interface.
Dim ns As NameSpace
Dim CurrentMailItem As MailItem
' We are going to refer to a mail folder (a MAPIFolder object)
Dim Inbox As MAPIFolder
Dim Item As Object
Dim Atmt As Attachment ' The attachment objects we will be looking for
Dim FileName As String ' Name and save path for each attachment
Dim a As Integer ' Number of attachments found
Dim i As Integer ' Number of items in the Inbox
Dim m As Integer ' Number of items moved
Dim strMsg As String
Set ns = GetNamespace("MAPI")
Set Inbox = ns.GetDefaultFolder(olFolderInbox)
a = 0 ' Init the number of attachments
i = 0 ' Init the number of items
If Inbox.Items.Count = 0 Then
MsgBox "There are no messages in the Inbox.", vbInformation, _
"Nothing Found"
Exit Sub
End If
' The Inbox does indeed contain something.
For Each Item In Inbox.Items
i = i + 1
For Each Atmt In Item.Attachments
a = a + 1
Next Atmt
strMsg = ""
If InStr(1, Item.Subject, "SR", vbTextCompare) Then
strMsg = strMsg & "This item pertains to an SR." & vbCrLf
strMsg = strMsg & "Subject: " & Item.Subject & vbCrLf
If MoveMail(Item, Inbox.Folders.Item("Processed").EntryID) Then
m = m + 1
strMsg = strMsg & "Item was moved!" & vbCrLf
Else
strMsg = strMsg & "The message was not moved!" & vbCrLf
End If
MsgBox strMsg, vbInformation, "Item #" & Str(i) & " Info"
End If
Next Item
strMsg = "I found " & i & " items in your Inbox." & vbCrLf
strMsg = strMsg & _
"I moved " & m & " files." & vbCrLf
MsgBox strMsg, vbInformation, "Finished!"
Analyze_Exit:
Set Atmt = Nothing
Set Item = Nothing
Set ns = Nothing


Exit Sub

Analyze_Err:
MsgBox "An unexpected error has occurred." & vbCrLf & _
"Please note and report the following information." & vbCrLf & _
"Macro name: Analyze" & vbCrLf & _
"Error Number: " & Err.Number & vbCrLf & _
"Error Description: " & Err.Description & vbCrLf _
, vbCritical, "Error!"
Resume Analyze_Exit
Exit Sub
End Sub

Private Function MoveMail(CurrentMailItem As MailItem, strTargFldrID As String) As Boolean
Dim CurrentNameSpace As NameSpace
Dim CurrentMoveMailItem As MailItem
Set CurrentNameSpace = Application.GetNamespace("MAPI")
On Error GoTo FINISH:
Set CurrentMoveMailItem = CurrentMailItem.Copy
CurrentMoveMailItem.Move _
DestFldr:=CurrentNameSpace.GetFolderFromID(strTarg FldrID)
'CurrMailItem.Delete
Err.Number = True
FINISH:
MoveMail = CBool(Err.Number)
End Function

[Matrix]

Outlook starts from Inbox by default. If you are dealing with folders outside of Inbox, you need to walk the folder hierarchy using the Folders collections. This link may help: http://www.outlookcode.com/d/code/getfolder.htm

Welcome to the forums.

[Microchip]

No, I can't walk yet. I am still crawling. Referring me to examples that are not specific to what I am trying to do does not do me any good. Sorry.

I am sure that someone who knows this stuff well can take a few minutes and cirrect the one or two line sof code in my example that need to be corrected. Thanks in advance!

[Matrix]

Sorry that I didn't make it clear. The reason for the error is explained in my previous post, here is the code changes (Tested on my Outlook 2003):

1. Add the function from http://www.outlookcode.com/d/code/getfolder.htm

Public Function GetFolder(strFolderPath As String)As MAPIFolder
' folder path needs to be something like
' "Public Folders\All Public Folders\Company\Sales"
Dim objApp As Outlook.Application
Dim objNS As Outlook.NameSpace
Dim colFolders As Outlook.Folders
Dim objFolder As Outlook.MAPIFolder
Dim arrFolders() As String
Dim I As Long
On Error Resume Next

strFolderPath = Replace(strFolderPath, "/", "\")
arrFolders() = Split(strFolderPath, "\")
Set objApp = CreateObject("Outlook.Application")
Set objNS = objApp.GetNamespace("MAPI")
Set objFolder = objNS.Folders.Item(arrFolders(0))
If Not objFolder Is Nothing Then
For I = 1 To UBound(arrFolders)
Set colFolders = objFolder.Folders
Set objFolder = Nothing
Set objFolder = colFolders.Item(arrFolders(I))
If objFolder Is Nothing Then
Exit For
End If
Next
End If

Set GetFolder = objFolder
Set colFolders = Nothing
Set objNS = Nothing
Set objApp = Nothing
End Function

2. Change

DestFldr:=CurrentNameSpace.GetFolderFromID(strTarg FldrID)

to

DestFldr:=GetFolder(strTargFldrID)

3. Change

If MoveMail(Item, Inbox.Folders.Item("Processed").EntryID) Then

to

If MoveMail(Item, "Personal Folders\outside") Then

Personal Folders\outside is the complete path of my test folder.

Please note that the changed code only deals with the folders outside of "Inbox".

[Microchip]

Hurricane, thank you SO Much for that help. I was stuck on this for weeks. Support and assistance like yours will go a long way, because as I learn from generous people like you, I, too, will be able to share what I have learned.

People like you make this world a better place.

Thanks again!!!
Dave

[Matrix]

Glad it helps.

[Microchip]

How do I run that program without going into the Visual Basic editor every time? I don't want it to run automatically, becaus eit never knows when the last e-mail is coming in. I want to run it after I see all of the e-mail finishing. Can I hook it up to a macro name, an dthen a function key, perhaps?

Thanks!

[Matrix]

You can run a macro from the outlook with the menu "Tools | Macro | Macros...", select the macro in the list.

An easier way, you can add the macro to the toolbar:
1. Select the menu "Toolbars | Customize".
2. Switch to the Commands tab.
3. Under Categories, select Macros.
4. Drag the macro to the desired toolbar.
4. Right-click on the new toolbar button, then change the Name or button appearance as desired.

[Microchip]

Very slick. Thank you again! I am impressed.