Microsoft visual basic: Compile error expected end with

[jjxxoo]

MICROSOFT VISUAL BASIC: COMPILE ERROR EXPECTED END WITH


I am expected to fix this code but am unsure how i keep rearranging things but get error codes and it wont let me run the code. If someone can help please.

Sub Formatting()
 
 ' Objective
 ' Name
 ' Date
 
    With Worksheets("Formatting")
        
        With .Range("A1")
            .Value = "Expenses For March"
            With .Font
                .Name = "Arial"
                .Bold = True
                .ColorIndex = 5
                .Size = 14
         End With
         
          With .Interior
                .ColorIndex = 2
            End With
            
            .HorizontalAlignment = xlLeft
        End With
        
        With Range("A3:A6")
            .InsertIndent 1
            With .Font
                .Italic = True
                .Bold = True
                .ColorIndex = 3
            End With
            
            With .Range("B3:B6")
                .Interior.ColorIndex = 37
                .NumberFormat = "$#,##0"
            End With
        
        End With 

End Sub

[macropod]

Not only are you missing the required final 'End With', your 'With .Range("B3:B6") ... End With' block is logically inside your 'With Range("A3:A6") ... End With' block. All this would be readily apparent if you structured your code more consistently and avoided 'With ... End With' blocks containing only one element. For example:

Sub Formatting()
With Worksheets("Formatting")
    With .Range("A1")
        .Value = "Expenses For March"
        With .Font
            .Name = "Arial"
            .Bold = True
            .ColorIndex = 5
            .Size = 14
        End With
        .Interior.ColorIndex = 2
        .HorizontalAlignment = xlLeft
    End With
    
    With .Range("A3:A6")
        .InsertIndent 1
        With .Font
            .Italic = True
            .Bold = True
            .ColorIndex = 3
        End With
    End With
    
    With .Range("B3:B6")
        .Interior.ColorIndex = 37
        .NumberFormat = "$#,##0"
    End With
End With
End Sub

Your 'With Range("A3:A6") ... End With' block should also be 'With .Range("A3:A6") ... End With'.