Need good source on 2007 graphics features

[samhdc]

We have been saving out files down to be compatible with 2003, but we will soon stop. We have large Word documents (up to 500 pages) with hundreds of linked images. I need a source that will explain the differences between graphics in 2003 and in 2007, especially regarding linked images. In the past, I have relied heavily on being able to toggle between a linked image and it's file path, a feature that has been especially useful when links have corrupted--I can show the file path and then use Find and Replace to insert a corrected file path. This doesn't seem possible in 2007. Regardless, I will need to educate people on what they can do with the graphics in 2007 that they couldn't do in 2003. Thanks!

[macropod]

Hi samhdc,

With your existing documents, you should be able to toggle between the image and field code display via Alt-F9/Shift-F9 as before. Likewise for any documents created in Word 2007 that you save in the 97-2003 .doc format. For the newer .docx/.docm format, you can still find the image names & paths via Office Button|Prepare|Links (or Alt-E, k - the same shortcut you'd use in Office 2003).

[samhdc]

Thanks for your reply, Paul. We do use the toggle with our existing docs, but soon we will stop saving down to 2003. The problem I have with the Prepare/Edit Links box is that I can't tell what the pathname is for a specific link. For example, if a link is broken, how do I tell what the filename is for that picture so that I can fix it? Before, I could toggle and see it immediately. Also, if all of the links break because of a server disruption (has happened numerous time), how do I reconnect all the links without reinserting all of the images? (Before, I could search and replace on the filepath names) Can I select all of the images in the Edit Links box and direct them to a specific folder? What if images come from different folders? (maps vs photos, for example). Do you see what I mean? I was hoping maybe somewhere out there, someone had a website or a book explaining how to work with images in Word 2007.

[macropod]

Hi samhdc,

In the case of a server disruption, the links should 'repair' as soon as the server is back online. At most, you might need to force Word to update them, especially if you've got the 'update automatic links at open' option set (see Word Options|Advanced).

I'm curious about the suggestion that individual links are breaking. That would usually suggest the image had been deleted from the folder concerned. I should also point out that toggling to view the field code only every worked for in-line images. Nevertheless, it's quite easy to obtain and change the link info for a given image with a macro.

[samhdc]

Hi Paul,
Thanks again for your response. Most of the time, the links do repair themselves (sometime we have to force the update), but occasionally they do not, and since we frequently work with 50-100+ photos in a file, we need a way to fix them that is not one image at a time. In the cases where the links do break, when we look at the filepath, it has switched to the user's C drive or somehow been corrupted. The figure files are still in the original directory. We have talked to our IT people about it, but they don't know why it would happen either. All of our images are inline.

Where would I get info on a macro for this? Or additional info on how the graphics are different in 2007 than in 2003, and what new capabilities it offers?

Also, in 2007 format, how do I know the filename for any given image? If I select the image and then look at Edit Links, it does not indicate which image I've selected.

[macropod]

Hi samhdc,

Here are two macros for updating image links. They both handle inline and floating images. The first one processes all images in the document; the second one processes only the selected image(s).

Sub UpdateAllImageLinks()
Dim oShp As Shape, iShp As InlineShape, RngStry As Range, OldPath As String, NewPath As String
With ThisDocument
  For Each RngStry In .StoryRanges
    For Each oShp In RngStry.ShapeRange
      With oShp
        .Select
        If Not .LinkFormat Is Nothing Then
          OldPath = .LinkFormat.SourcePath
          NewPath = InputBox("Update Path", "Image Path Update", OldPath)
          If NewPath = "" And OldPath <> "" Then Exit Sub
          ' Replace the link to the external file if they differ.
          If OldPath <> NewPath Then
            .LinkFormat.SourceFullName = Replace(.LinkFormat.SourceFullName, OldPath, NewPath)
          End If
        End If
      End With
    Next oShp
    For Each iShp In .InlineShapes
      With iShp
        .Select
        If Not .LinkFormat Is Nothing Then
          OldPath = .LinkFormat.SourcePath
          NewPath = InputBox("Update Path", "Image Path Update", OldPath)
          If NewPath = "" And OldPath <> "" Then Exit Sub
          ' Replace the link to the external file if they differ.
          If OldPath <> NewPath Then
            .LinkFormat.SourceFullName = Replace(.LinkFormat.SourceFullName, OldPath, NewPath)
          End If
        End If
      End With
    Next iShp
  Next RngStry
End With
End Sub

Sub UpdateOneImageLink()
Dim oShp As Shape, iShp As InlineShape, RngStry As Range, OldPath As String, NewPath As String
With Selection
  For Each oShp In .ShapeRange
    With oShp
      If Not .LinkFormat Is Nothing Then
        OldPath = .LinkFormat.SourcePath
        NewPath = InputBox("Update Path", "Image Path Update", OldPath)
        If NewPath = "" And OldPath <> "" Then Exit Sub
        ' Replace the link to the external file if they differ.
        If OldPath <> NewPath Then
          .LinkFormat.SourceFullName = Replace(.LinkFormat.SourceFullName, OldPath, NewPath)
        End If
      End If
    End With
  Next oShp
  For Each iShp In .InlineShapes
    With iShp
      If Not .LinkFormat Is Nothing Then
        OldPath = .LinkFormat.SourcePath
        NewPath = InputBox("Update Path", "Image Path Update", OldPath)
        If NewPath = "" And OldPath <> "" Then Exit Sub
        ' Replace the link to the external file if they differ.
        If OldPath <> NewPath Then
          .LinkFormat.SourceFullName = Replace(.LinkFormat.SourceFullName, OldPath, NewPath)
        End If
      End If
    End With
  Next iShp
End With
End Sub

[samhdc]

Thanks, Paul! Can you direct me to where in the macro I would add in (or substitute) the correct file path (as opposed to the older false path)?

[macropod]

Hi samhdc,

When you run the macro, it pops up an inputbox for each linked image, with the image's old/current path shown as the default. You simply replace that with the new/correct path.