Sub Test()
    With CreateObject("WIA.ImageFile")
        .LoadFile "C:\Test\image.jpg"
        With .Properties("GpsLatitude").Value
            Debug.Print .Item(1).Value + .Item(2).Value / 60 + .Item(3).Value / 3600
        End With
        With .Properties("GpsLongitude").Value
            Debug.Print .Item(1).Value + .Item(2).Value / 60 + .Item(3).Value / 3600
        End With
    End With
End Sub

Sub AddPics()
Dim xlApp As Object, xlWkBk As Object, StrWkBkNm As String, StrWkSht As String
Dim StrRpt As String, StrDocPath As String, StrPicPath As String, xlFList As String, xlCList As String
Dim iDataRow As Long, c As Long, r As Long, i As Long, j As Long, k As Long, NumCols As Long
Dim iShp As InlineShape, oTbl As Table, TblWdth As Single, RwHght As Single, ColWdth As Single
StrWkBkNm = "Workbook path & name"
StrDocPath = ActiveDocument.Path
StrRpt = Right(StrDocPath, Len(StrDocPath) - InStrRev(StrDocPath, "\"))
StrWkSht = StrRpt & " Observations"
StrPicPath = StrDocPath & "\" & StrRpt & " Report Photos\"
If Dir(StrWkBkNm) = "" Then
  MsgBox "Cannot find the designated workbook: " & StrWkBkNm, vbExclamation
  Exit Sub
End If
On Error GoTo ErrExit
NumCols = CLng(InputBox("How Many Columns per Row?"))
RwHght = CentimetersToPoints(CSng(InputBox("What max height for the pictures, in centimeters (e.g. 5)?")))
On Error GoTo 0: On Error Resume Next
'Start Excel
Set xlApp = CreateObject("Excel.Application")
If xlApp Is Nothing Then
  MsgBox "Can't start Excel.", vbExclamation
  Exit Sub
End If
On Error GoTo 0
With xlApp
  'Hide our Excel session
  .Visible = False
  ' The file is available, so open it.
  Set xlWkBk = .Workbooks.Open(FileName:=StrWkBkNm, ReadOnly:=True, AddToMru:=False)
  If xlWkBk Is Nothing Then
    MsgBox "Cannot open:" & vbCr & StrWkBkNm, vbExclamation
    .Quit: Exit Sub
  End If
  ' Process the workbook.
  With xlWkBk
    'Ensure the worksheet exists
    If SheetExists(xlWkBk, StrWkSht) = True Then
      With .Worksheets(StrWkSht)
        ' Find the last-used row in column A.
        iDataRow = .Cells(.Rows.Count, 14).End(-4162).Row ' -4162 = xlUp
        ' Capture the F/R data.
        For i = 2 To iDataRow
          ' Skip over empty fields to preserve the underlying cell contents.
          If Trim(.Range("N" & i)) <> vbNullString Then
            xlFList = xlFList & "|" & Trim(.Range("N" & i))
            xlCList = xlCList & "|" & Trim(.Range("Q" & i))
          End If
        Next
      End With
    Else
      MsgBox "Cannot find the designated worksheet: " & StrWkSht, vbExclamation
    End If
  .Close False
  End With
  .Quit
End With
' Release Excel object memory
Set xlWkBk = Nothing: Set xlApp = Nothing
'Exit if there are no data
If xlFList = "" Then Exit Sub
'Initialise the 'Microsoft Windows Image Acquisition' library
Dim WIAFile As Object, WIAProp As Object: Set WIAFile = CreateObject("WIA.ImageFile")
Dim StrNm As String, StrLon As String, EW As String, StrLat As String, NS As String
With ActiveDocument
  For i = 1 To .Styles.Count
    With .Styles(i)
      If .Name = "TblPic" Then bFnd = False: Exit For
    End With
  Next
  If bFnd = False Then .Styles.Add Name:="TblPic", Type:=wdStyleTypeParagraph
  With .Styles("TblPic").ParagraphFormat
    .Alignment = wdAlignParagraphCenter
    .KeepWithNext = True
    .SpaceAfter = 0
    .SpaceBefore = 0
  End With
  With .Styles("Caption")
    .ParagraphFormat.SpaceAfter = 6
    With .Font
      .Name = "Times New Roman"
      .Size = 10
      .Bold = False
    End With
    .ParagraphFormat.TabStops.Add Position:=CentimetersToPoints(2.5), Alignment:=wdAlignTabLeft
  End With
  With .Styles("Table")
    .ParagraphFormat.Alignment = wdAlignParagraphCenter
    .ParagraphFormat.SpaceAfter = 6
    With .Font
      .Name = "Times New Roman"
      .Size = 10
      .Bold = True
    End With
  End With
  'Add a 2-row by NumCols-column table to take the images
  Set oTbl = Selection.Tables.Add(Range:=Selection.Range, NumRows:=2, NumColumns:=NumCols)
  With .PageSetup
    TblWdth = .PageWidth - .LeftMargin - .RightMargin - .Gutter
    ColWdth = TblWdth / NumCols
  End With
  With oTbl
    .AutoFitBehavior (wdAutoFitFixed)
    .Columns.Width = ColWdth
  End With
  CaptionLabels.Add Name:="Photograph"
  'Process each file from the F/R List
  k = UBound(Split(xlFList, "|"))
  For i = 1 To k Step NumCols
    r = ((i - 1) / NumCols + 1) * 2 - 1
    'Format the rows
    Call FormatRows(oTbl, r, RwHght)
    For c = 1 To NumCols
      j = j + 1
      'Insert the Picture
      Set iShp = .InlineShapes.AddPicture( _
        FileName:=StrPicPath & Split(xlFList, "|")(j) & ".jpg", LinkToFile:=False, _
        SaveWithDocument:=True, Range:=oTbl.Cell(r, c).Range)
      With iShp
        .LockAspectRatio = True
        If (.Width < ColWdth) And (.Height < RwHght) Then
          .Width = ColWdth
          If .Height > RwHght Then .Height = RwHght
        End If
      End With
      'Get the GPS Data
      StrLat = "N/A": NS = "": StrLon = "N/A": EW = ""
      WIAFile.LoadFile StrPicPath & StrNm & ".jpg"
      With WIAFile
        If .Properties.Exists("GpsLongitudeRef") Then NS = .Properties("GpsLongitudeRef").Value
        If .Properties.Exists("GpsLongitude") Then
          With .Properties("GpsLongitude")
            StrLon = NS & .Value(1) & Chr(186) & .Value(2) & Chr(39) & .Value(3) & Chr(34)
            'StrLon = NS & .Value(1) + .Value(2) / 60 + .Value(3) / 3600
          End With
        End If
        If .Properties.Exists("GpsLatitudeRef") Then EW = .Properties("GpsLatitudeRef").Value
        If .Properties.Exists("GpsLatitude") Then
          With .Properties("GpsLatitude")
            StrLat = EW & .Value(1) & Chr(186) & .Value(2) & Chr(39) & .Value(3) & Chr(34)
            'StrLat = EW & .Value(1) + .Value(2) / 60 + .Value(3) / 3600
          End With
        End If
      End With
      'Insert the Caption & GPS Co-ordinates on the row below the picture
      With oTbl.Cell(r + 1, c).Range
        .InsertBefore vbCr
        .Characters.First.InsertCaption _
          Label:="Photograph", Title:=vbTab & Split(xlCList, "|")(j), _
          Position:=wdCaptionPositionBelow, ExcludeLabel:=False
        .Characters.First = vbNullString
        '.Characters.Last.Previous = vbNullString
        With .Characters.Last
          .Text = "GPS: " & StrLon & "; " & StrLat
          .Style = "Table"
        End With
      End With
      'Exit when we're done
      If j = k Then Exit For
    Next
    'Add extra rows as needed
    If j < k Then
      oTbl.Rows.Add
      oTbl.Rows.Add
    End If
  Next
End With
ErrExit:
Application.ScreenUpdating = True
End Sub

Function SheetExists(xlWkBk As Object, SheetName As String) As Boolean
Dim i As Long: SheetExists = False
For i = 1 To xlWkBk.Sheets.Count
  If xlWkBk.Sheets(i).Name = SheetName Then
    SheetExists = True:   Exit For
  End If
Next
End Function

Sub FormatRows(oTbl As Table, x As Long, RwHght As Single)
With oTbl
  With .Rows(x)
    .Height = RwHght
    .HeightRule = wdRowHeightExactly
    .Range.Style = "TblPic"
    .Cells.VerticalAlignment = wdCellAlignVerticalCenter
  End With
  With .Rows(x + 1)
    .Height = CentimetersToPoints(1.25)
    .HeightRule = wdRowHeightExactly
    .Range.Style = "Caption"
  End With
End With
End Sub

            StrLon = NS & .Value(1) & Chr(186) & .Value(2) & Chr(39) & .Value(3) & Chr(34)
            'StrLon = NS & .Value(1) + .Value(2) / 60 + .Value(3) / 3600
...
            StrLat = EW & .Value(1) & Chr(186) & .Value(2) & Chr(39) & .Value(3) & Chr(34)
            'StrLat = EW & .Value(1) + .Value(2) / 60 + .Value(3) / 3600

Option Explicit
Sub AddPicsWithGPSCoordinates()
Dim oStyle As Style, lngIndex As Long, oShp As InlineShape
Dim oTbl As Table, sngTblWidth As Single, strGPS As String, sngRowHght As Single, sngColWdth As Single
  Application.ScreenUpdating = False
  With ActiveDocument.PageSetup
    sngTblWidth = .PageWidth - .LeftMargin - .RightMargin - .Gutter
  End With
  'These are fixed values in points. You can modify here or use the original input box method.
  sngColWdth = 300
  sngRowHght = 180
  With Application.FileDialog(msoFileDialogFilePicker)
    .Title = "Select image files and click OK"
    .Filters.Add "Images", "*.gif; *.jpg; *.jpeg; *.bmp; *.tif; *.png"
    .FilterIndex = 2
    If .Show = -1 Then
      With ActiveDocument
        On Error Resume Next
        Set oStyle = .Styles("TblPic")
        If oStyle Is Nothing Then Set oStyle = .Styles.Add(Name:="TblPic", Type:=wdStyleTypeParagraph)
        On Error GoTo 0
        With oStyle.ParagraphFormat
          .Alignment = wdAlignParagraphCenter
          .KeepWithNext = True
          .SpaceAfter = 0
          .SpaceBefore = 0
        End With
      End With
      Set oTbl = Selection.Tables.Add(Range:=Selection.Range, NumRows:=1, NumColumns:=2)
      With oTbl
        .AutoFitBehavior (wdAutoFitFixed)
        .TopPadding = 0
        .BottomPadding = 0
        .LeftPadding = 0
        .RightPadding = 0
        .Spacing = 0
        .Columns(1).Width = sngColWdth
        .Columns(2).Width = sngTblWidth - sngColWdth
        .Borders.Enable = True
        With .Rows(1)
         .Height = sngRowHght
         .HeightRule = wdRowHeightExactly
         .Range.Style = "TblPic"
         .Cells.VerticalAlignment = wdCellAlignVerticalCenter
        End With
      End With
      For lngIndex = 1 To .SelectedItems.Count
        'Insert the Picture
        Set oShp = ActiveDocument.InlineShapes.AddPicture( _
          FileName:=.SelectedItems(lngIndex), LinkToFile:=False, _
           SaveWithDocument:=True, Range:=oTbl.Cell(lngIndex, 1).Range)
        With oShp
          .LockAspectRatio = True
          If (.Width < sngColWdth) And (.Height < sngRowHght) Then
            .Width = sngColWdth
            If .Height > sngRowHght Then .Height = sngRowHght
          End If
        End With
        'Get the Image name for the Caption
        strGPS = fcnGetGPSInfo(.SelectedItems(lngIndex))
        oTbl.Cell(lngIndex, 2).Range.Text = "Location" & vbCr & strGPS
        oTbl.Rows.Add
      Next lngIndex
      oTbl.Rows.Last.Delete
    End If
  End With
ErrExit:
  Application.ScreenUpdating = True
End Sub

Function fcnGetGPSInfo(strPath) As String
'You will need to set a reeference to Microsoft Windows Image Acquisition library
Dim WIAFile As Object, WIAProp As Object
Dim strLat As String, NS As String, strLong As String, EW As String

  strLat = "N/A": NS = "": strLong = "N/A": EW = ""
  Set WIAFile = CreateObject("WIA.ImageFile")
  WIAFile.LoadFile strPath
  With WIAFile
    If .Properties.Exists("GpsLongitudeRef") Then NS = .Properties("GpsLongitudeRef").Value
    If .Properties.Exists("GpsLongitude") Then
      With .Properties("GpsLongitude")
        'Seconds rounded to four decimal places
        strLong = NS & .Value(1) & Chr(186) & .Value(2) & Chr(39) & Format(.Value(3), "0.0000") & Chr(34)
        'strLong = NS & .Value(1) + .Value(2) / 60 + .Value(3) / 3600
      End With
    End If
    If .Properties.Exists("GpsLatitudeRef") Then EW = .Properties("GpsLatitudeRef").Value
    If .Properties.Exists("GpsLatitude") Then
      With .Properties("GpsLatitude")
        'Seconds rounded to four decimal places
        strLat = EW & .Value(1) & Chr(186) & .Value(2) & Chr(39) & Format(.Value(3), "0.0000") & Chr(34)
       'StrLat = EW & .Value(1) + .Value(2) / 60 + .Value(3) / 3600
      End With
    End If
  End With
  fcnGetGPSInfo = strLat & vbCr & strLong
  Set WIAFile = Nothing
lbl_Exit:
  Exit Function
End Function