Sub UpdateDocuments()
Application.ScreenUpdating = False
Dim strFolder As String, strFile As String, strDocNm As String, wdDoc As Document, Shp As Shape, iShp As InlineShape
strDocNm = ActiveDocument.FullName
strFolder = GetFolder
If strFolder = "" Then Exit Sub
strFile = Dir(strFolder & "\*.doc", vbNormal)
While strFile <> ""
  If strFolder & "\" & strFile <> strDocNm Then
    Set wdDoc = Documents.Open(FileName:=strFolder & "\" & strFile, AddToRecentFiles:=False, Visible:=False)
    With wdDoc
      For Each Shp In .Shapes
        With Shp
          Select Case .Type
            Case msoPicture, msoLinkedPicture: .PictureFormat.Brightness = .PictureFormat.Brightness * 1.25
          End Select
        End With
      Next
      For Each iShp In .InlineShapes
        With iShp
          Select Case .Type
            Case wdInlineShapePicture, wdInlineShapeLinkedPicture: .PictureFormat.Brightness = .PictureFormat.Brightness * 1.25
          End Select
        End With
      Next
      .Close SaveChanges:=True
    End With
  End If
  strFile = Dir()
Wend
Set wdDoc = Nothing
Application.ScreenUpdating = True
End Sub

Function GetFolder() As String
Dim oFolder As Object
GetFolder = ""
Set oFolder = CreateObject("Shell.Application").BrowseForFolder(0, "Choose a folder", 0)
If (Not oFolder Is Nothing) Then GetFolder = oFolder.Items.Item.Path
Set oFolder = Nothing
End Function